{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }: {
    nixosConfigurations = {
      alpha = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          {
            boot.loader.grub.devices = [ "/dev/sda" ];
            fileSystems."/" = {
              device = "/dev/sda1";
            };
            system.stateVersion = "24.11";
          }
        ];
      };
    };
    colmena =
      let
        confs = self.nixosConfigurations;
      in
      {
        meta = {
          description = "my personal machines";
          # This can be overriden by node nixpkgs
          nixpkgs = import nixpkgs { system = "x86_64-linux"; };
          nodeNixpkgs = builtins.mapAttrs (name: value: value.pkgs) confs;
          nodeSpecialArgs = builtins.mapAttrs (name: value: value._module.specialArgs) confs;
        };
      } // builtins.mapAttrs
        (name: value: {
          imports = value._module.args.modules ++ [
            # The following undo some Colmena specific settings, ensuring that `nixos-rebuild` and `colmena build` result in the exact same result.
            {
              system.nixos.revision = nixpkgs.rev;
              system.nixos.versionSuffix = ".${builtins.substring 0 8 nixpkgs.lastModifiedDate}.${nixpkgs.shortRev}";
            }
          ];
        })
        confs;
  };
}