Python: Check for insecure versions of SSL and TLS.

taus-semmle · taus-semmle · commit 0a839f8468d0 · 2019-01-07T15:24:15.000+01:00
diff --git a/python/ql/src/Security/CWE-327/InsecureDefaultProtocol.ql b/python/ql/src/Security/CWE-327/InsecureDefaultProtocol.ql
@@ -0,0 +1,27 @@
+/**
+ * @name Default version of SSL/TLS may be insecure
+ * @description No SSL/TLS version has been specified in a call to 'ssl.wrap_socket'.
+ *              This may result in an insecure protocol being used.
+ * @id py/insecure-default-protocol
+ * @kind problem
+ * @problem.severity warning
+ * @precision high
+ * @tags security
+ *       external/cwe/cwe-327
+ */
+
+import python
+
+FunctionObject ssl_wrap_socket() {
+    result = any(ModuleObject ssl | ssl.getName() = "ssl").getAttribute("wrap_socket")
+}
+
+from CallNode call
+where 
+    call = ssl_wrap_socket().getACall() and
+    not exists(call.getArgByName("ssl_version"))
+select call, "Call to ssl.wrap_socket does not specify a protocol, which may result in an insecure default being used."
+
+
+
+
diff --git a/python/ql/src/Security/CWE-327/InsecureProtocol.ql b/python/ql/src/Security/CWE-327/InsecureProtocol.ql
@@ -0,0 +1,60 @@
+/**
+ * @name Use of insecure SSL/TLS version
+ * @description An insecure version of SSL/TLS has been specified. This may
+ *              leave the connection open to attacks.
+ * @id py/insecure-protocol
+ * @kind problem
+ * @problem.severity warning
+ * @precision high
+ * @tags security
+ *       external/cwe/cwe-327
+ */
+
+import python
+
+FunctionObject ssl_wrap_socket() {
+    result = any(ModuleObject ssl | ssl.getName() = "ssl").getAttribute("wrap_socket")
+}
+
+string insecure_version_name() {
+    // For the `ssl` module
+    result = "SSLv2_METHOD" or
+    result = "SSLv23_METHOD" or
+    result = "SSLv3_METHOD" or
+    result = "TLSv1_METHOD" or
+    // For `pyOpenSSL.SSL`
+    result = "PROTOCOL_SSLv2" or
+    result = "PROTOCOL_SSLv3" or
+    result = "PROTOCOL_TLSv1"
+}
+
+private ModuleObject the_ssl_module() {
+    result = any(ModuleObject m | m.getName() = "ssl")
+}
+
+private ModuleObject the_pyOpenSSL_module() {
+    result = any(ModuleObject m | m.getName() = "pyOpenSSL").getAttribute("SSL")
+}
+
+predicate unsafe_ssl_wrap_method_call(CallNode call) {
+    call = ssl_wrap_socket().getACall() and
+    exists(ControlFlowNode arg | arg = call.getArgByName("ssl_version") |
+        arg.(AttrNode).getObject(insecure_version_name()).refersTo(the_ssl_module())
+    )
+}
+
+ClassObject the_pyOpenSSL_Context_class() {
+    result = any(ModuleObject m | m.getName() = "pyOpenSSL.SSL").getAttribute("Context")
+}
+
+predicate unsafe_pyOpenSSL_Context_call(CallNode call) {
+    call = the_pyOpenSSL_Context_class().getACall() and
+    call.getArgByName("method").refersTo(the_pyOpenSSL_module().getAttribute(insecure_version_name()))
+}
+
+from CallNode call, string method_name
+where
+    unsafe_ssl_wrap_method_call(call) and method_name = "ssl.wrap_socket"
+or
+    unsafe_pyOpenSSL_Context_call(call) and method_name = "pyOpenSSL.SSL.Context"
+select call, "Insecure SSL/TLS protocol version specified in call to " + method_name + "."
diff --git a/python/ql/test/query-tests/Security/CWE-327/InsecureDefaultProtocol.expected b/python/ql/test/query-tests/Security/CWE-327/InsecureDefaultProtocol.expected
@@ -0,0 +1 @@
+| InsecureProtocol.py:35:1:35:17 | ControlFlowNode for Attribute() | Call to ssl.wrap_socket does not specify a protocol, which may result in an insecure default being used. |
diff --git a/python/ql/test/query-tests/Security/CWE-327/InsecureDefaultProtocol.qlref b/python/ql/test/query-tests/Security/CWE-327/InsecureDefaultProtocol.qlref
@@ -0,0 +1 @@
+Security/CWE-327/InsecureDefaultProtocol.ql
diff --git a/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.expected b/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.expected
@@ -0,0 +1,8 @@
+| InsecureProtocol.py:5:1:5:47 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to ssl.wrap_socket. |
+| InsecureProtocol.py:6:1:6:47 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to ssl.wrap_socket. |
+| InsecureProtocol.py:7:1:7:47 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to ssl.wrap_socket. |
+| InsecureProtocol.py:9:1:9:36 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to pyOpenSSL.SSL.Context. |
+| InsecureProtocol.py:10:1:10:37 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to pyOpenSSL.SSL.Context. |
+| InsecureProtocol.py:11:1:11:36 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to pyOpenSSL.SSL.Context. |
+| InsecureProtocol.py:12:1:12:36 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to pyOpenSSL.SSL.Context. |
+| InsecureProtocol.py:27:1:27:26 | ControlFlowNode for Attribute() | Insecure SSL/TLS protocol version specified in call to pyOpenSSL.SSL.Context. |
diff --git a/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.py b/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.py
@@ -0,0 +1,35 @@
+import ssl
+from pyOpenSSL import SSL
+
+# true positives
+ssl.wrap_socket(ssl_version=ssl.PROTOCOL_SSLv2)
+ssl.wrap_socket(ssl_version=ssl.PROTOCOL_SSLv3)
+ssl.wrap_socket(ssl_version=ssl.PROTOCOL_TLSv1)
+
+SSL.Context(method=SSL.SSLv2_METHOD)
+SSL.Context(method=SSL.SSLv23_METHOD)
+SSL.Context(method=SSL.SSLv3_METHOD)
+SSL.Context(method=SSL.TLSv1_METHOD)
+
+# not relevant
+wrap_socket(ssl_version=ssl.PROTOCOL_SSLv3)
+wrap_socket(ssl_version=ssl.PROTOCOL_TLSv1)
+wrap_socket(ssl_version=ssl.PROTOCOL_SSLv2)
+
+Context(method=SSL.SSLv3_METHOD)
+Context(method=SSL.TLSv1_METHOD)
+Context(method=SSL.SSLv2_METHOD)
+Context(method=SSL.SSLv23_METHOD)
+
+# true positive using flow
+
+METHOD = SSL.SSLv2_METHOD
+SSL.Context(method=METHOD)
+
+# secure versions
+
+ssl.wrap_socket(ssl_version=ssl.PROTOCOL_TLSv1_1)
+SSL.Context(method=SSL.TLSv1_1_METHOD)
+
+# possibly insecure default
+ssl.wrap_socket()
diff --git a/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.qlref b/python/ql/test/query-tests/Security/CWE-327/InsecureProtocol.qlref
@@ -0,0 +1 @@
+Security/CWE-327/InsecureProtocol.ql
diff --git a/python/ql/test/query-tests/Security/CWE-327/options b/python/ql/test/query-tests/Security/CWE-327/options
@@ -1 +1,2 @@
 semmle-extractor-options: -p ../lib/ --max-import-depth=3
+optimize: true
diff --git a/python/ql/test/query-tests/Security/lib/pyOpenSSL/SSL.py b/python/ql/test/query-tests/Security/lib/pyOpenSSL/SSL.py
@@ -0,0 +1,10 @@
+SSLv2_METHOD = 1
+SSLv3_METHOD = 2
+SSLv23_METHOD = 3
+TLSv1_METHOD = 4
+TLSv1_1_METHOD = 5
+TLSv1_2_METHOD = 6
+
+class Context(object):
+    def __init__(self, *args, **kwargs):
+        pass
diff --git a/python/ql/test/query-tests/Security/lib/pyOpenSSL/__init__.py b/python/ql/test/query-tests/Security/lib/pyOpenSSL/__init__.py

Original file line number	Diff line number	Diff line change
`@@ -0,0 +1 @@`
	`1`	`+\| InsecureProtocol.py:35:1:35:17 \| ControlFlowNode for Attribute() \| Call to ssl.wrap_socket does not specify a protocol, which may result in an insecure default being used. \|`
Original file line number	Diff line number	Diff line change
`@@ -0,0 +1 @@`
	`1`	`+Security/CWE-327/InsecureDefaultProtocol.ql`
Original file line number	Diff line number	Diff line change
`@@ -1 +1,2 @@`
`1`	`1`	`semmle-extractor-options: -p ../lib/ --max-import-depth=3`
	`2`	`+optimize: true`