Convert type-parameter-out-of-scope warning into consistency query

smowton · igfoo · commit 7fe260c1a2d7 · 2022-05-10T19:51:17.000+01:00
The warning in the extractor is inaccurate due to references to enclosing types' type parameters. A consistency query can check that the type parameter is indeed in scope exploiting broader knowledge of the enclosing types.
diff --git a/java/kotlin-extractor/src/main/kotlin/KotlinUsesExtractor.kt b/java/kotlin-extractor/src/main/kotlin/KotlinUsesExtractor.kt
@@ -863,11 +863,7 @@ open class KotlinUsesExtractor(
 
     fun useTypeParameter(param: IrTypeParameter) =
         TypeResult(
-            tw.getLabelFor<DbTypevariable>(getTypeParameterLabel(param)) {
-                // Any type parameter that is in scope should have been extracted already
-                // in extractClassSource or extractFunction
-                logger.error("Missing type parameter label")
-            },
+            tw.getLabelFor<DbTypevariable>(getTypeParameterLabel(param)),
             useType(eraseTypeParameter(param)).javaResult.signature,
             param.name.asString()
         )
diff --git a/java/ql/consistency-queries/typeParametersInScope.ql b/java/ql/consistency-queries/typeParametersInScope.ql
@@ -0,0 +1,39 @@
+import java
+
+Type getAMentionedType(RefType type) {
+  result = type
+  or
+  result = getAMentionedType(type).(Array).getElementType()
+  or
+  result = getAMentionedType(type).(ParameterizedType).getATypeArgument()
+  or
+  result = getAMentionedType(type).(NestedType).getEnclosingType()
+}
+
+Type getATypeUsedInClass(RefType type) {
+  // Base cases:
+  result = type.getAField().getType()
+  or
+  result = type.getAMethod().getReturnType()
+  or
+  result = type.getAMethod().getParameterType(_)
+  or
+  result = any(Expr e | e.getEnclosingCallable().getDeclaringType() = type).getType()
+  // Structural recursion over types:
+  or
+  result = getAMentionedType(getATypeUsedInClass(type))
+}
+
+TypeVariable getATypeVariableInScope(RefType type) {
+  result = type.getACallable().(GenericCallable).getATypeParameter()
+  or
+  result = type.(GenericType).getATypeParameter()
+  or
+  result = getAMentionedType(type.(ParameterizedType).getATypeArgument())
+  or
+  result = getATypeVariableInScope(type.getEnclosingType())
+}
+
+from ClassOrInterface typeUser, TypeVariable outOfScope
+where outOfScope = getAMentionedType(typeUser) and not outOfScope = getATypeVariableInScope(typeUser)
+select "Type " + typeUser + " uses out-of-scope type variable " + outOfScope
