; ---------------------------------------------------------------------------------------

; Name: SweetyVD

; Description: Sweety Visual Designer

; dependency: SweetyVDmodule.pbi (Sweety Visual Designer Module)

; Author: ChrisR

; Date: 2017-05-25

; Version: 1.9.5.1

; PB-Version: 5.60 (x86/x64)

; OS: Windows, Linux, Mac

; Credit: Stargâte: Transformation of gadgets at runtime

; Falsam: Tiny Visual Designer (TVD)

; blueb: FullColorRequester

; Zebuddi: Add PreFix and SuFix for variable (eg: iButton_1.i)

; English-Forum: http://www.purebasic.fr/english/viewtopic.php?f=27&t=68187

; French-Forum: http://www.purebasic.fr/french/viewtopic.php?f=3&t=16527

; Github: https://github.com/ChrisRfr/SweetyVD

; ---------------------------------------------------------------------------------------

; Note Linux: In order to use the WebGadget you have to utilize WebKitGTK

; See Shardik's post http://www.purebasic.fr/english/viewtopic.php?f=15&t=54049

; To install the Gtk3 libraries on Debian/Ubuntu: sudo apt-get install libwebkitgtk-3.0-0

; ---------------------------------------------------------------------------------------

CompilerIf #PB_Compiler_IsMainFile

EnableExplicit

#BuildVersion = "1.9.5.1"

;Import internal function

CompilerSelect #PB_Compiler_OS

CompilerCase #PB_OS_Windows

#PB_IDE = "purebasic.exe" ;File name relative to #PB_Compiler_Home

#PB_MessageRequester_Error=16

#PB_MessageRequester_Warning=48

#PB_MessageRequester_Info=64

Import ""

CompilerCase #PB_OS_Linux

#PB_IDE = "compilers/purebasic"

CompilerIf #PB_Compiler_Processor = #PB_Processor_x86

ImportC "/usr/lib/i386-linux-gnu/libwebkitgtk-3.0.so.0" ;Ubuntu/Kubuntu/Xubuntu x86 with GTK3

CompilerElse

ImportC "/usr/lib/x86_64-linux-gnu/libwebkitgtk-3.0.so.0" ;Ubuntu/Kubuntu/Xubuntu x64 with GTK3

CompilerEndIf

CompilerCase #PB_OS_MacOS

#PB_IDE = "PureBasic.app"

ImportC ""

CompilerEndSelect

PB_Object_EnumerateStart( PB_Objects )

PB_Object_EnumerateNext( PB_Objects, *ID.Integer )

PB_Object_EnumerateAbort( PB_Objects )

PB_Object_GetObject( PB_Object , DynamicOrArrayID)

PB_Window_Objects.i

PB_Gadget_Objects.i

EndImport

;Dependency: SweetyVDmodule.pbi (Sweety Visual Designer Module)

XIncludeFile "SweetyVDmodule.pbi"

UseModule SVDesigner

IncludePath "Include"

XIncludeFile "LoadFontWML.pb"

XIncludeFile "GetPBIDE.pb"

XIncludeFile "GetTempFilename.pb"

XIncludeFile "DelOldFiles.pb"

XIncludeFile "TabBarGadget.pbi"

CompilerIf #PB_Compiler_OS = #PB_OS_Windows

XIncludeFile "FullColorRequester.pb"

CompilerEndIf

Enumeration

#MainWindow

#TimerId

#PopUpMenu

#EnableSVD

#CodeCreate

#SettingContainer

#SetDrawSizeText

#SetDrawWidth

#SetDrawSizeTextX

#SetDrawHeight

#DragText

#DragSpace

#ShowGrid

#GridSize

#AddMenu

#AddPopupMenu

#AddToolBar

#AddStatusBar

#GadgetList

#ListGadgets

#RenameGadgetButton

#DeleteGadgetButton

#HideGadget

#LockGadget

#DisableGadget

#PosGadgetX

#PosGadgetY

#PosGadgetWidth

#PosGadgetHeight

#ParentText

#ParentString

#ParentPick

;Properties

#PanelControls

#TreeControls

#CreateControlsList

#PropertiesContainer

#CaptionText

#CaptionString

#ToolTipText

#ToolTipString

#MiniText

#MiniString

#MaxiText

#MaxiString

#ImageText

#ImageString

#ImagePick

#FontText

#FontString

#FontPick

#FrontColorText

#FrontColorPick

#FrontColorImg

#BackColorText

#BackColorPick

#BackColorImg

#Constants

;Code Generator Windows

#CodeForm

#CodeNewTab

#CodeSave

#CodeClipboard

#CodeCancel

#Code_TitleBlock

#CodeEnumeration

#CodeVariable

#CodeConstants

#CodePBany

#FrameAdd

#CodeEventLoop

#CodeSeparator

#CodeCustomAddition

#CodeFrameOption

#CodeFrameColor

#CodeColorRGB

#CodeColorHex

#CodeFramePrePost

#TextGadget_PreFix

#StringGadget_PreFix

#CheckBox_Suffix

#CodeFrameIndent

#Text_SpaceIndent

#Spin_SpaceIndent

#CheckBox_TabIndent

#AboutButton

#AboutForm

#AboutBack

#Licence

;Rename Gadget Form

#RenameGadgetWindow

#RenameGadgetSharp

#RenameGadgetString

#RenameGadgetMsg

#RenameGadgetOK

#RenameGadgetCancel

#Shortcut_Escape

#Shortcut_Return

;Others

#Shortcut_Insert

#WinBarHeight

;JSON Gadget templates file

#JSONFile

EndEnumeration

Enumeration FormImage

#Vd_Unknow

#Img_Rename

#Img_Delete

#Img_About

EndEnumeration

#CountModelGadget = 32

Structure GadgetCtrl

GadgetCtrlImage.i

GadgetCtrlName.s

EndStructure

Global Dim GadgetCtrlArray.GadgetCtrl(0)

Structure ImageBtnPath

ImageBtn.i

ImagePath.s

EndStructure

Global NewList ImageBtnPathArray.ImageBtnPath()

Structure FontStruct

FontID.i

FontName.s

FontSize.i

FontStyle.i

EndStructure

Global NewList FontStructArray.FontStruct()

Structure ModelGadgetProperty ;Structure Gadget templates from Data Section

Model.s ;Gadget Model (ButtonGadget, TextGadget ........)

Order.i ;Tri

Type.i ;GadgetType

DftWidth.i ;Default Width

DftHeight.i ;Default Height

Name.s ;Name

Caption.s ;Caption, blank or content

Option1.s ;Option1

Option2.s ;Option2

Option3.s ;Option2

FrontColor.s ;FrontColor

BackColor.s ;FrontColor

ToolTip.s ;ToolTip

Image.i ;Image

Constants.s ;Available Constants (Ex: "#PB_Text_Center,#PB_Text_Right,#PB_Text_Border")

CustomIncludeFile.s ;Custom IncludeFile

CountGadget.i ;Gadget Counter by Model

EndStructure

Global Dim ModelGadget.ModelGadgetProperty(0)

Structure StructureGadget ;Structure of gadgets. Gadget 0 for OpenWindow

Gadget.i ;gadget Id

Model.s ;Gadget Model (ButtonGadget, TextGadget ........)

Type.i ;Type

Name.s ;Name

Vname.s ;Variable Name Prefix and Post Fix

X.i ;Pos X

Y.i ;Pos Y

Width.i ;Dim Width

Height.i ;Dim Height

Caption.s ;Caption Or Gadget content

ToolTip.s ;ToolTip

Option1.s ;Option1

Option2.s ;Option2

Option3.s ;Option2

FontID.i ;Font ID

FrontColor.s ;FrontColor

BackColor.s ;FrontColor

Constants.s ;Available Constants (Ex: "#PB_Text_Center,#PB_Text_Right,#PB_Text_Border")

Hide.b ;Hide Gadget

Disable.b ;Disable Gadget

Lock.b ;Lock Gadget

ModelType.i ;0=Window, 2=Gadget, 9=Gadget Deleted

Key.s ;ModelType + GadgetY(IdGadget) + GadgetX(IdGadget)

EndStructure

Global CountImageBtn.i, CountFontID.i, IdDrawGadgets.i = 1000000000

Global X.i, Y.i

Declare StartPrefs()

Declare ExitPrefs()

Declare LoadControls()

Declare InitModelWindow()

Declare InitModelgadget()

Declare InitJSONModelGadget()

Declare SaveJSONModelGadget()

Declare RenameGadgetForm(IdGadget.i)

Declare RenameGadget(IdGadget.i)

Declare CreateGadgets(Model.s)

Declare InitWindowSelected()

Declare InitProperties()

Declare LoadGadgetProperties(IdGadget.i)

Declare RemoveFont(FontID.i)

Declare SelectFont(IdGadget.i)

Declare RemoveImage(sImagePath.s)

Declare DrawSelectedImage(IdGadget.i)

Declare ResizeDrawArea(Width.i, Height.i)

Declare WindowSize()

Declare OpenMainWindow(Designer_Width,Designer_Height, X = 0, Y = 0)

Declare Init()

Declare Exit()

UsePNGImageDecoder()

UseJPEGImageDecoder()

;Code Create Form and Code creation

XIncludeFile "CodeCreate.pb"

Procedure StartPrefs()

Global Designer_Width.i = 1000

Global Designer_Height.i = 660

UserScreen_Width.i = 640

UserScreen_Height.i = 480

DragSpace = 10

ShowGrid = #True

GridSize = 20

If OpenPreferences("SweetyVD.ini", #PB_Preference_GroupSeparator) = 0 ;Create Default SweetyVD.ini setting

;Canvas_Size_X = 1600 not working

CreatePreferences("SweetyVD.ini", #PB_Preference_GroupSeparator)

PreferenceComment("The size of the drawing area (OpenWindow) is defined in the Gadget templates: SweetyVD.json file")

;PreferenceComment("SaveOnExit Save Designer_Width, Designer_Height, Designer_Maximize, Drag_Space, Show_Grid and Grid_Size on Exit")

;PreferenceComment("Boolean value 0/1: SaveOnExit, Designer_Maximize, Show_Grid, Include_TitleBlock, Include_Enumeration, Variable, Add_StatusBar, Include_EventLoop")

PreferenceComment("")

PreferenceGroup("Designer")

WritePreferenceLong("SaveOnExit", 1)

WritePreferenceLong("Designer_Width", Designer_Width)

WritePreferenceLong("Designer_Height", Designer_Height)

WritePreferenceLong("UserScreen_Width", UserScreen_Width)

WritePreferenceLong("UserScreen_Height", UserScreen_Height)

WritePreferenceLong("Designer_Maximize", 0)

WritePreferenceLong("ScrollArea_MaxWidth", 1920)

WritePreferenceLong("ScrollArea_MaxHeight", 1020)

WritePreferenceLong("Drag_Space", DragSpace)

WritePreferenceLong("Show_Grid", ShowGrid)

WritePreferenceLong("Grid_Size", GridSize)

;Init Code Create Window

PreferenceGroup("CodeCreate")

WritePreferenceLong("Include_TitleBlock", 1)

WritePreferenceLong("Include_Enumeration", 1)

WritePreferenceLong("Variable", 0)

WritePreferenceLong("Include_EventLoop", 1)

WritePreferenceLong("Include_CustomAddition", 0)

PreferenceGroup("CodeOption")

WritePreferenceLong("Hexa_Color", 0)

PreferenceComment("Pre/Post fixes for Variables")

WritePreferenceString("PreFix", "i")

WritePreferenceString("Suffix", ".i")

WritePreferenceLong("Suffix_Enabled", 1)

WritePreferenceLong("Space_Indentation", 2)

WritePreferenceLong("Tab_Indentation", 0)

;Default Title Block

PreferenceGroup("TitleBlock")

PreferenceComment("Use FormatDate (%yyyy, %yy, %mm, %dd + Separator) to format the current date, variable: %Date%")

PreferenceComment("The Key name must start with " + #DQUOTE$ +"Line" + #DQUOTE$)

WritePreferenceString("FormatDate", "%yyyy-%mm-%dd")

WritePreferenceString("Line01", "; -----------------------------------------------------------------------------")

WritePreferenceString("Line02", "; Name:")

WritePreferenceString("Line03", "; Description:")

WritePreferenceString("Line04", "; Author:")

WritePreferenceString("Line05", "; Date: %Date%")

WritePreferenceString("Line06", "; Version:")

WritePreferenceString("Line07", "; PB-Version:")

WritePreferenceString("Line08", "; OS:")

WritePreferenceString("Line09", "; Credit:")

WritePreferenceString("Line10", "; Forum:")

WritePreferenceString("Line11", "; Created by: SweetyVD")

WritePreferenceString("Line12", "; -----------------------------------------------------------------------------")

;Include Custom Addition

PreferenceGroup("CustomAddition")

PreferenceComment("Include a dot " + #DQUOTE$ + "." + #DQUOTE$ + " as first character To include spaces at the beginning of a Line (eg: indentation)")

PreferenceComment("The Key name must start With " + #DQUOTE$ + "Line" + #DQUOTE$)

PreferenceGroup("CustomAddition_Include")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Constante")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Structure")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Variable")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Declare")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Procedure")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Init")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Main")

WritePreferenceString("Line01", "")

PreferenceGroup("CustomAddition_Exit")

WritePreferenceString("Line01", "")

ClosePreferences()

Else ;Read Global variables

PreferenceGroup("Designer")

Designer_Width = ReadPreferenceLong("Designer_Width", Designer_Width) ; default values

Designer_Height = ReadPreferenceLong("Designer_Height", Designer_Height)

UserScreen_Width = ReadPreferenceLong("UserScreen_Width", UserScreen_Width)

UserScreen_Height = ReadPreferenceLong("UserScreen_Height", UserScreen_Height)

DragSpace = ReadPreferenceLong("Drag_Space", DragSpace)

ShowGrid = ReadPreferenceLong("Show_Grid", ShowGrid)

GridSize = ReadPreferenceLong("Grid_Size", GridSize)

ClosePreferences()

EndIf

EndProcedure

Procedure ExitPrefs()

Protected Designer_Maximize.b

If OpenPreferences("SweetyVD.ini", #PB_Preference_GroupSeparator) = 0 : StartPrefs() : EndIf

If GetWindowState(#MainWindow) = #PB_Window_Maximize : Designer_Maximize = #True : EndIf

If OpenPreferences("SweetyVD.ini", #PB_Preference_GroupSeparator)

PreferenceGroup("Designer")

If ReadPreferenceLong("SaveOnExit", 1) = 1

WritePreferenceLong("Designer_Width", Designer_Width)

WritePreferenceLong("Designer_Height", Designer_Height)

WritePreferenceLong("Designer_Maximize", Designer_Maximize)

WritePreferenceLong("UserScreen_Width", GetGadgetState(#SetDrawWidth))

WritePreferenceLong("UserScreen_Height", GetGadgetState(#SetDrawHeight))

WritePreferenceLong("Drag_Space", GetGadgetState(#DragSpace))

WritePreferenceLong("Show_Grid", GetGadgetState(#ShowGrid))

WritePreferenceLong("Grid_Size", GetGadgetState(#GridSize))

ClosePreferences()

EndIf

EndIf

EndProcedure

Procedure LoadControls()

Protected ZipFile.i, GadgetName.s, GadgetImageSize.i, *GadgetImage, GadgetImage, GadgetCtrlCount.l

Define ZipFileTheme.s = GetCurrentDirectory()+"SilkTheme.zip"

If FileSize(ZipFileTheme) < 1

CompilerIf #PB_Compiler_OS = #PB_OS_Windows

ZipFileTheme = #PB_Compiler_Home+"themes\SilkTheme.zip"

CompilerElse

ZipFileTheme = #PB_Compiler_Home+"themes/SilkTheme.zip"

CompilerEndIf

If FileSize(ZipFileTheme) < 1

MessageRequester("SweetyVD Error", "SilkTheme.zip Not found in the current directory" +#CRLF$+ "Or in PB_Compiler_Home\themes directory" +#CRLF$+#CRLF$+ "Exit now", #PB_MessageRequester_Error|#PB_MessageRequester_Ok)

End

EndIf

EndIf

CompilerIf #PB_Compiler_Version > 522

UseZipPacker()

CompilerEndIf

GadgetImage = CatchImage(#PB_Any,?Vd_Unknow)

GadgetCtrlArray(GadgetCtrlCount)\GadgetCtrlImage=GadgetImage

GadgetCtrlArray(GadgetCtrlCount)\GadgetCtrlName="Unknow"

ZipFile = OpenPack(#PB_Any, ZipFileTheme, #PB_PackerPlugin_Zip)

If ZipFile

If ExaminePack(ZipFile)

While NextPackEntry(ZipFile)

GadgetName = PackEntryName(ZipFile)

GadgetName = ReplaceString(GadgetName,"chart_bar","vd_tabbargadget") ;use chart_bar png for TabBarGadget

GadgetName = ReplaceString(GadgetName,"page_white_edit","vd_scintillagadget") ;vd_scintillagadget.png not found. Use page_white_edit.png instead

GadgetName = ReplaceString(GadgetName,"frame3dgadget","framegadget") ;vd_framegadget.png not found. Use vd_frame3dgadget.png instead

If FindString(Left(GadgetName, 3), "vd_")

GadgetImageSize = PackEntrySize(ZipFile)

*GadgetImage = AllocateMemory(GadgetImageSize)

UncompressPackMemory(ZipFile, *GadgetImage, GadgetImageSize)

GadgetImage = CatchImage(#PB_Any, *GadgetImage, GadgetImageSize)

GadgetName = LCase(GadgetName)

GadgetName = ReplaceString(GadgetName,".png","")

GadgetName = ReplaceString(GadgetName,"vd_","")

Select PackEntryType(ZipFile)

Case #PB_Packer_File

If GadgetImage

GadgetCtrlCount + 1

ReDim GadgetCtrlArray(GadgetCtrlCount)

GadgetCtrlArray(GadgetCtrlCount)\GadgetCtrlImage=GadgetImage

GadgetCtrlArray(GadgetCtrlCount)\GadgetCtrlName=GadgetName

EndIf

EndSelect

FreeMemory(*GadgetImage)

EndIf

Wend

EndIf

ClosePack(ZipFile)

EndIf

EndProcedure

Procedure InitModelWindow() ;Initializing Window Templates

Protected I.i

For I=0 To ArraySize(ModelGadget())

If ModelGadget(I)\Type = 0 ;OpenWindow

With ModelGadget(I)

;Draw Area Width and Height with associated Spin Gadgets

\DftWidth = UserScreen_Width

\DftHeight = UserScreen_Height

SetGadgetState(#PosGadgetWidth, \DftWidth)

SetGadgetState(#PosGadgetHeight, \DftHeight)

SetGadgetState(#SetDrawWidth, \DftWidth)

SetGadgetState(#SetDrawHeight, \DftHeight)

;DrawArea Size max Width and max Height

DrawAreaSize(\DftWidth, \DftHeight)

;Save window information in the gadget List. Element 0

AddMapElement(SVDListGadget(), Str(#MainWindow))

SVDListGadget()\Gadget=#MainWindow

SVDListGadget()\Model="OpenWindow"

SVDListGadget()\Type=0

SVDListGadget()\Name="#"+\Name+"_0"

If Mid(\Caption, 7) <> "" ;"#Text:blabla"

SVDListGadget()\Caption=\Caption

Else

SVDListGadget()\Caption="#Text:" + \Name+"_0"

EndIf

SVDListGadget()\Option1=\Option1

SVDListGadget()\Option2=\Option2

SVDListGadget()\Option3=\Option3

SVDListGadget()\FrontColor=\FrontColor

SVDListGadget()\BackColor=\BackColor

SVDListGadget()\ToolTip=\ToolTip

SVDListGadget()\Constants=\Constants

SVDListGadget()\ModelType=0

;Add Window to List Gadgets ComboBox. Element 0 for the Window Draw Area

AddGadgetItem(#ListGadgets, -1, SVDListGadget()\Name)

SetGadgetState(#ListGadgets, 0)

SetGadgetItemData(#ListGadgets, 0, 0)

AddGadgetItem(#TreeControls, -1, SVDListGadget()\Name, ImageID(\Image), 0)

SetGadgetState(#TreeControls, 0)

SetGadgetItemData(#TreeControls, 0, 0)

EndWith

Break

EndIf

Next

EndProcedure

Procedure InitModelgadget() ;Initializing Gadget Templates

Protected Buffer.s, GadgetCtrlFound.b, I.i, J.i

Restore ModelGadgets

ReDim ModelGadget(#CountModelGadget)

For I=0 To #CountModelGadget

With ModelGadget(I)

For J=1 To 14

Read.s Buffer

Select J

Case 1 : \Model=Buffer

Case 2 : \Order=Val(Buffer)

Case 3 : \Type=Val(Buffer)

Case 4 : \DftWidth=Val(Buffer)

Case 5 : \DftHeight=Val(Buffer)

Case 6 : \Name=Buffer

Case 7 : \Caption=Buffer

Case 8 : \Option1=Buffer

Case 9 : \Option2=Buffer

Case 10 : \Option3=Buffer

Case 11 : \FrontColor=Buffer

Case 12 : \BackColor=Buffer

Case 13 : \ToolTip=Buffer

Case 14 : \Constants=Buffer

EndSelect

Next

Next

EndWith

;JSON file Gadget sorted by Order (could be by Gadget Name or by Gadget type)

SortStructuredArray(ModelGadget(), #PB_Sort_Ascending, OffsetOf(ModelGadgetProperty\Order), TypeOf(ModelGadgetProperty\Order))

;SortStructuredArray(ModelGadget(), #PB_Sort_Ascending, OffsetOf(ModelGadgetProperty\Model), TypeOf(ModelGadgetProperty\Model))

;SortStructuredArray(ModelGadget(), #PB_Sort_Ascending, OffsetOf(ModelGadgetProperty\Type), TypeOf(ModelGadgetProperty\Type))

SaveJSONModelGadget()

For I=0 To #CountModelGadget

With ModelGadget(I)

Select \Type

Case 0 ;OpenWindow

\Image=CatchImage(#PB_Any,?Vd_Window)

InitModelWindow() ;Draw Area Width and Height and Save Window information

Case 50 ;Custom Gadget

\Image=CatchImage(#PB_Any,?Vd_Custom)

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

Default

GadgetCtrlFound = #False

For J = 1 To ArraySize(GadgetCtrlArray()) ;Load Popup Menu Image and ListIcon Controls Gadgets with Image

If GadgetCtrlArray(J)\GadgetCtrlName = LCase(\Model)

GadgetCtrlFound = #True

\Image=GadgetCtrlArray(J)\GadgetCtrlImage

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

EndIf

Next

If GadgetCtrlFound = #False ;If image not found, use Vd_Unknow.png

\Image=GadgetCtrlArray(0)\GadgetCtrlImage

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

EndIf

EndSelect

Next

EndWith

EndProcedure

Procedure InitJSONModelGadget()

Protected GadgetCtrlFound.b, I.i, J.i

If CreateJSON(#JSONFile)

LoadJSON(#JSONFile, "SweetyVD.json")

ExtractJSONArray(JSONValue(#JSONFile), ModelGadget())

; Load Image from GadgetCtrlArray and load Popup Menu Image and ListIcon Controls Gadgets

For I=0 To ArraySize(ModelGadget())

With ModelGadget(I)

Select \Type

Case 0

\Image=CatchImage(#PB_Any,?Vd_Window)

InitModelWindow() ;Draw Area Width and Height and Save Window information

Case 50 ;Custom Gadget

\Image=CatchImage(#PB_Any,?Vd_Custom)

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

Default

GadgetCtrlFound = #False

For J = 1 To ArraySize(GadgetCtrlArray()) ;Load Popup Menu Image and ListIcon Controls Gadgets with Image

If GadgetCtrlArray(J)\GadgetCtrlName = LCase(\Model)

GadgetCtrlFound = #True

\Image=GadgetCtrlArray(J)\GadgetCtrlImage

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

EndIf

Next

If GadgetCtrlFound = #False ;If image not found, use Vd_Unknow.png

\Image=GadgetCtrlArray(0)\GadgetCtrlImage

AddGadgetItem(#CreateControlsList, -1, \Model, ImageID(\Image))

MenuItem(I, \Model, ImageID(\Image)) ;Add to popup menu

EndIf

EndSelect

Next

EndWith

EndIf

EndProcedure

Procedure SaveJSONModelGadget()

CreateJSON(#JSONFile) ;Create JSON file

InsertJSONArray(JSONValue(#JSONFile), ModelGadget()) ;Insert ModelGadget list in JSON file

SaveJSON(#JSONFile, "SweetyVD.json", #PB_JSON_PrettyPrint) ;Save JSON file

EndProcedure

Procedure RenameGadgetForm(IdGadget.i)

If OpenWindow(#RenameGadgetWindow, WindowX(#MainWindow)+GadgetX(#ScrollDrawArea)+1, WindowY(#MainWindow)+GadgetY(#GadgetList)+GadgetY(#ListGadgets)+4, 172, 72, "Rename Gadget",#PB_Window_TitleBar)

StickyWindow(#RenameGadgetWindow, #True)

AddKeyboardShortcut(#RenameGadgetWindow, #PB_Shortcut_Escape, #Shortcut_Escape)

AddKeyboardShortcut(#RenameGadgetWindow, #PB_Shortcut_Return, #Shortcut_Return)

TextGadget(#RenameGadgetSharp, 2, 7, 10, 20, "#")

StringGadget(#RenameGadgetString, 14, 4, 154, 22, "")

If FindMapElement(SVDListGadget(), Str(IdGadget))

SetGadgetText(#RenameGadgetString, Mid(SVDListGadget()\Name,2))

EndIf

TextGadget(#RenameGadgetMsg, 2, 30, 168, 16, "")

ButtonGadget(#RenameGadgetOK, 63, 50, 50, 18, "OK")

ButtonGadget(#RenameGadgetCancel, 118, 50, 50, 18, "Cancel")

SetActiveGadget(#RenameGadgetString)

EndIf

EndProcedure

Procedure RenameGadget(IdGadget.i)

Protected RenameGadgetString.s, InvalidName.b, I.i

RenameGadgetString = GetGadgetText(#RenameGadgetString)

If RenameGadgetString = ""

SetGadgetText(#RenameGadgetMsg, "Enter a Name")

SetGadgetText(#RenameGadgetString, Mid(RenameGadgetString,2))

InvalidName = #True

ElseIf Left(RenameGadgetString, 1) = "#"

SetGadgetText(#RenameGadgetMsg, "# as 1st Char removed")

SetGadgetText(#RenameGadgetString, Mid(RenameGadgetString,2))

InvalidName = #True

Else

ForEach SVDListGadget() ;Name already used

If SVDListGadget()\Gadget <> IdGadget And SVDListGadget()\Name = "#" + RenameGadgetString + "_"

SetGadgetText(#RenameGadgetMsg, "Name already used")

InvalidName = #True

Break

EndIf

Next

If InvalidName = #False

For I=0 To ArraySize(ModelGadget())

If ModelGadget(I)\Name = Left(RenameGadgetString, Len(ModelGadget(I)\Name)) ;Name defined in Model Gadget: SweetyVD.json

SetGadgetText(#RenameGadgetMsg, "Name is reserved (Model)")

InvalidName = #True

Break

EndIf

Next

EndIf

EndIf

If InvalidName = #False

If FindMapElement(SVDListGadget(), Str(IdGadget))

SVDListGadget()\Name = "#" + RenameGadgetString

SetGadgetItemText(#TreeControls, GetGadgetState(#TreeControls), RenameGadgetString)

SetGadgetItemText(#ListGadgets, GetGadgetState(#ListGadgets), RenameGadgetString)

EndIf

RemoveKeyboardShortcut(#RenameGadgetWindow, #PB_Shortcut_Escape)

RemoveKeyboardShortcut(#RenameGadgetWindow, #PB_Shortcut_Return)

CloseWindow(#RenameGadgetWindow)

Else

SetActiveGadget(#RenameGadgetString)

EndIf

EndProcedure

Procedure CreateGadgets(Model.s)

Protected IdGadget.i, ModelType.i, DrawGadget.b, TmpCaption.s, Mini.i, Maxi.i, StepValue.i, I.i

InitProperties()

OpenGadgetList(#ScrollDrawArea) ;Required when changing apps(ex: test generated code) to reopen the GadgetList

For I=0 To ArraySize(ModelGadget())

If ModelGadget(I)\Model = Model

With ModelGadget(I)

\CountGadget=\CountGadget+1 ;Updating the gadget counter by model

ParentPosDim() ;#ScrollDrawArea

X = GridMatch(X, DragSpace, MinX, MaxX-\DftWidth) ;Align on Grid and remains inside the grid

Y = GridMatch(Y, DragSpace, MinY, MaxY-\DftHeight)

;Default values from the gadget models table

Select Left(\Caption, 5)

Case "#Text", "#TabN"

If Mid(\Caption, 7) <> "" ;If empty, nothing and no comma for the default value

TmpCaption=Mid(\Caption, 7) ;"#Text:blabla"

Else

TmpCaption=\Name+"_"+Str(\CountGadget) ;Caption=#Text:blabla => "blabla", or ""

EndIf

Case "#Date"

TmpCaption=Mid(\Caption, 7) ;#Date:%dd/%mm/%yyyy

Case "#Dir$"

TmpCaption=Mid(\Caption, 7) ;"#Dir$:C:\blabla\"

Case "#Url$"

TmpCaption=Mid(\Caption, 7) ;"#Url$:https://www.purebasic.fr/"

Default : TmpCaption=""

EndSelect

ModelType=2

DrawGadget=#False

Select Model ;Create Gadget depending on model

Case "ButtonGadget" : IdGadget=ButtonGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "ButtonImageGadget" : IdGadget=ButtonImageGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, 0)

Case "CalendarGadget" : IdGadget= CalendarGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, 0)

Case "CanvasGadget"

IdGadget=CanvasGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

If StartDrawing(CanvasOutput(IdGadget))

DrawText(5, 5, \Name+"_"+Str(\CountGadget), #Blue, #White)

StopDrawing()

EndIf

Case "CheckBoxGadget" : IdGadget=CheckBoxGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "ComboBoxGadget"

IdGadget=ComboBoxGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, #PB_ComboBox_Editable)

AddGadgetItem(Idgadget,-1,TmpCaption)

Case "ContainerGadget"

ModelType=1

DrawGadget=#True

IdDrawGadgets=IdDrawGadgets+1

IdGadget=IdDrawGadgets

;IdGadget=ContainerGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

;CloseGadgetList()

Case "DateGadget" : IdGadget=DateGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "EditorGadget"

IdGadget=EditorGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, #PB_Editor_ReadOnly)

AddGadgetItem(IdGadget, 0, \Name+"_"+Str(\CountGadget))

Case "ExplorerComboGadget" : IdGadget =ExplorerComboGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, "")

Case "ExplorerListGadget" : IdGadget=ExplorerListGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, "")

Case "ExplorerListGadget" : IdGadget=ExplorerListGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, "")

Case "FrameGadget"

DrawGadget=#True

IdDrawGadgets=IdDrawGadgets+1

IdGadget=IdDrawGadgets

;IdGadget=FrameGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "HyperLinkGadget" : IdGadget=HyperLinkGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption, RGB(0,0,128))

Case "ImageGadget" ;We cheat with a Canvas instead of an ImageGadget

IdGadget=CanvasGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

If StartDrawing(CanvasOutput(IdGadget))

DrawText(5, 5, \Name+"_"+Str(\CountGadget), #Blue, #White)

StopDrawing()

EndIf

Case "IPAddressGadget"

IdGadget= IPAddressGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

SetGadgetState(IdGadget, MakeIPAddress(127, 0, 0, 1))

Case "ListIconGadget" : IdGadget=ListIconGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption, 100)

Case "ListViewGadget" : IdGadget=ListViewGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

Case "OpenGLGadget" : IdGadget=OpenGLGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

Case "OptionGadget" : IdGadget=OptionGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "PanelGadget"

ModelType=1

DrawGadget=#True

IdDrawGadgets=IdDrawGadgets+1

IdGadget=IdDrawGadgets

;IdGadget=PanelGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

;AddGadgetItem(IdGadget, -1, TmpCaption)

;DisableGadget(IdGadget,#True)

;CloseGadgetList()

Case "ProgressBarGadget"

Mini = Val(Mid(\Option1, 7)) : Maxi = Val(Mid(\Option2, 7))

IdGadget=ProgressBarGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, Mini, Maxi)

SetGadgetState(IdGadget, Mini+(Maxi-Mini)*2/3)

Case "ScintillaGadget"

If InitScintilla()

IdGadget=ScintillaGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, 0)

EndIf

Case "ScrollAreaGadget"

ModelType=1

DrawGadget=#True

IdDrawGadgets=IdDrawGadgets+1

IdGadget=IdDrawGadgets

;InnerWidth, InnerHeight

Mini = Val(Mid(\Option1, 7)) : Maxi = Val(Mid(\Option2, 7)) : StepValue = Val(Mid(\Option3, 7))

;IdGadget=ScrollAreaGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, Mini, Maxi, StepValue)

;CloseGadgetList()

Case "ScrollBarGadget"

Mini = Val(Mid(\Option1, 7)) : Maxi = Val(Mid(\Option2, 7))

IdGadget=ScrollBarGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, Mini, Maxi, 0)

Case "SpinGadget"

Mini = Val(Mid(\Option1, 7)) : Maxi = Val(Mid(\Option2, 7))

IdGadget=SpinGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, Mini, Maxi, #PB_Spin_Numeric)

SetGadgetState(IdGadget, Mini+(Maxi-Mini)*2/3)

Case "StringGadget"

IdGadget=StringGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption, #PB_String_ReadOnly)

Case "TextGadget" : IdGadget=TextGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "TrackBarGadget"

Mini = Val(Mid(\Option1, 7)) : Maxi = Val(Mid(\Option2, 7))

IdGadget=TrackBarGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, Mini, Maxi)

SetGadgetState(IdGadget, Mini+(Maxi-Mini)*2/3)

Case "TreeGadget" : IdGadget=TreeGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

Case "WebGadget" : IdGadget=WebGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, TmpCaption)

Case "TabBarGadget"

IdGadget=TabBarGadget(#PB_Any, X, Y, \DftWidth, \DftHeight, #TabBarGadget_BottomLine|#TabBarGadget_CloseButton, #MainWindow)

AddTabBarGadgetItem(IdGadget, #PB_Default, TmpCaption)

Default

If Model <> "" And \Name <> "" And \DftWidth > 0 And \DftHeight > 0

IdGadget=CanvasGadget(#PB_Any, X, Y, \DftWidth, \DftHeight)

If StartDrawing(CanvasOutput(IdGadget))

DrawText(5, 5, \Name+"_"+Str(\CountGadget), #Blue, #White)

StopDrawing()

EndIf

EndIf

EndSelect

CompilerIf #PB_Compiler_OS = #PB_OS_MacOS

If DrawGadget = #False : DisableGadget(IdGadget, #True) : EndIf

CompilerEndIf

;Save gadget information in the gadget map List

AddMapElement(SVDListGadget(), Str(IdGadget))

SVDListGadget()\Gadget=Idgadget

SVDListGadget()\Model=Model

SVDListGadget()\Type=\Type

SVDListGadget()\Name="#"+\Name+"_"+Str(\CountGadget)

SVDListGadget()\ParentGadget = #ScrollDrawArea

SVDListGadget()\ParentElement = 0

SVDListGadget()\X =X

SVDListGadget()\Y=Y

SVDListGadget()\Width=\DftWidth

SVDListGadget()\Height=\DftHeight

SVDListGadget()\DrawGadget = DrawGadget

;Default values from the gadget models table

Select Left(\Caption, 5)

Case "#Text" : SVDListGadget()\Caption = "#Text:" + TmpCaption

Case "#Date" : SVDListGadget()\Caption = "#Date:" + TmpCaption

Case "#Dir$" : SVDListGadget()\Caption = "#Dir$:" + TmpCaption

Case "#Url$" : SVDListGadget()\Caption = "#Url$:" + TmpCaption

Case "#TabN" : SVDListGadget()\Caption = "#TabN:" + TmpCaption

Default : SVDListGadget()\Caption=\Caption

EndSelect

SVDListGadget()\Option1=\Option1

SVDListGadget()\Option2=\Option2

SVDListGadget()\Option3=\Option3

SVDListGadget()\FrontColor=\FrontColor

SVDListGadget()\BackColor=\BackColor

SVDListGadget()\ToolTip=\ToolTip

SVDListGadget()\Constants=\Constants

SVDListGadget()\ModelType=ModelType

SVDListGadget()\DrawGadget=DrawGadget

;Add Gadget to List Gadgets ComboBox with IdGadget as Data. Element 0 is reserved for Window Draw Area

AddGadgetItem(#ListGadgets, -1, SVDListGadget()\Name)

SetGadgetState(#ListGadgets, CountGadgetItems(#ListGadgets)-1)

SetGadgetItemData(#ListGadgets, CountGadgetItems(#ListGadgets)-1, IdGadget)

AddGadgetItem(#TreeControls, -1, SVDListGadget()\Name, ImageID(\Image), 1)

SetGadgetState(#TreeControls, CountGadgetItems(#TreeControls)-1)

SetGadgetItemData(#TreeControls, CountGadgetItems(#TreeControls)-1, IdGadget)

;Add Drag Handle Gadget in module

If DrawGadget = #False

AddSVDGadget(IdGadget, Model)

Else

AddSVDDrawGadget(IdGadget, Model)

EndIf

EndWith

Break

EndIf

Next

EndProcedure

Procedure InitWindowSelected()

SetGadgetState(#ListGadgets, #MainWindow)

SetGadgetState(#TreeControls, #MainWindow)

SetGadgetState(#PosGadgetX, 0) : SetGadgetState(#PosGadgetY, 0)

SetGadgetState(#PosGadgetWidth, GetGadgetState(#SetDrawWidth)) : SetGadgetState(#PosGadgetHeight, GetGadgetState(#SetDrawHeight))

LoadGadgetProperties(#MainWindow)

DisableGadget(#DeleteGadgetButton,#True)

HideGadget(#HideGadget, #True) : HideGadget(#DisableGadget, #True) : HideGadget(#LockGadget, #True)

DisableGadget(#PosGadgetX, #True) : DisableGadget(#PosGadgetY, #True)

;HideGadget(#ParentText, #True) : HideGadget(#ParentString, #True) : HideGadget(#ParentPick, #True)

HideGadget(#FontText, #True) : HideGadget(#FontString, #True) : HideGadget(#FontPick, #True)

;HideGadget(#AddMenu, #False) : HideGadget(#AddPopupMenu, #False) : HideGadget(#AddToolBar, #False) : HideGadget(#AddStatusBar, #False)

EndProcedure

Procedure InitProperties()

;HideGadget(#AddMenu, #True) : HideGadget(#AddPopupMenu, #True) : HideGadget(#AddToolBar, #True) : HideGadget(#AddStatusBar, #True)

DisableGadget(#CaptionString,#True)

DisableGadget(#ToolTipString,#False)

DisableGadget(#DeleteGadgetButton,#False)

HideGadget(#HideGadget, #False) : HideGadget(#DisableGadget, #False) : HideGadget(#LockGadget, #False)

;HideGadget(#ParentText, #False) : HideGadget(#ParentString, #False) : HideGadget(#ParentPick, #False)

HideGadget(#ParentText, #True) : HideGadget(#ParentString, #True) : HideGadget(#ParentPick, #True)

HideGadget(#MiniText, #True) : HideGadget(#MiniString, #True)

HideGadget(#MaxiText, #True) : HideGadget(#MaxiString, #True)

HideGadget(#ImageText, #True) : HideGadget(#ImageString, #True) : HideGadget(#ImagePick, #True)

HideGadget(#FontText, #False) : HideGadget(#FontString, #False) : HideGadget(#FontPick, #False)

HideGadget(#FrontColorText, #True) : HideGadget(#FrontColorPick, #True)

HideGadget(#BackColorText, #True) : HideGadget(#BackColorPick, #True)

SetGadgetText(#CaptionText, "") : SetGadgetText(#CaptionString, "")

SetGadgetText(#ToolTipText, "ToolTip") : SetGadgetText(#ToolTipString, "")

SetGadgetText(#MiniText, "Mini") : SetGadgetText(#MaxiText, "Maxi")

SetGadgetText(#MiniString, "") : SetGadgetText(#MaxiString, "")

SetGadgetText(#ImageString, "")

ClearGadgetItems(#Constants)

EndProcedure

Procedure LoadGadgetProperties(IdGadget.i)

Protected TmpConstants.s, sFontString.s, I.i

InitProperties()

With SVDListGadget()

If FindMapElement(SVDListGadget(), Str(IdGadget))

SetGadgetState(#HideGadget, \Hide)

SetGadgetState(#DisableGadget, \Disable)

SetGadgetState(#LockGadget, \Lock)

DisableGadget(#PosGadgetX, \Lock) : DisableGadget(#PosGadgetY, \Lock) : DisableGadget(#PosGadgetWidth, \Lock) : DisableGadget(#PosGadgetHeight, \Lock)

Select Left(\Caption, 5)

Case "#Text"

SetGadgetText(#CaptionText, "Text")

SetGadgetText(#CaptionString, Mid(\Caption, 7)) : DisableGadget(#CaptionString,#False)

Case "#Date"

SetGadgetText(#CaptionText, "Fmt Date")

SetGadgetText(#CaptionString, Mid(\Caption, 7)) : DisableGadget(#CaptionString,#False)

Case "#Dir$"

SetGadgetText(#CaptionText, "Ini Folder")

SetGadgetText(#CaptionString, Mid(\Caption, 7)) : DisableGadget(#CaptionString,#False)

Case "#Url$"

SetGadgetText(#CaptionText, "Url")

SetGadgetText(#CaptionString, Mid(\Caption, 7)) : DisableGadget(#CaptionString,#False)

Case "#TabN"

SetGadgetText(#CaptionText, "Tab name")

SetGadgetText(#CaptionString, Mid(\Caption, 7)) : DisableGadget(#CaptionString,#False)

EndSelect

If \Model = "ScrollAreaGadget" : SetGadgetText(#MiniText, "InnerW") : SetGadgetText(#MaxiText, "InnerH") : EndIf

If Left(\ToolTip, 5) = "#Nooo"

SetGadgetText(#ToolTipText, "")

DisableGadget(#ToolTipString,#True)

Else

SetGadgetText(#ToolTipString, \ToolTip)

EndIf

Select Left(\Option1, 5)

Case "#Mini", "#InrW"

SetGadgetText(#MiniString, Mid(\Option1, 7))

HideGadget(#MiniText, #False)

HideGadget(#MiniString, #False)

Case "#Imag"

SetGadgetText(#ImageString, Mid(\Option1, 7))

HideGadget(#ImageText, #False)

HideGadget(#ImageString, #False)

HideGadget(#ImagePick, #False)

EndSelect

Select Left(\Option2, 5)

Case "#Maxi", "#InrH"

SetGadgetText(#MaxiString, Mid(\Option2, 7))

HideGadget(#MaxiText, #False)

HideGadget(#MaxiString, #False)

EndSelect

If \FontID = 0

SetGadgetText(#FontString, "")

Else

ResetList(FontStructArray())

While NextElement(FontStructArray())

If FontStructArray()\FontID = \FontID

sFontString = FontStructArray()\FontName + " " + Str(FontStructArray()\FontSize)

If FontStructArray()\FontStyle

sFontString + " "

If FontStructArray()\FontStyle & #PB_Font_Bold

sFontString + "B"

EndIf

If FontStructArray()\FontStyle & #PB_Font_Italic

sFontString + "I"

EndIf

If FontStructArray()\FontStyle & #PB_Font_StrikeOut

sFontString + "S"

EndIf

If FontStructArray()\FontStyle & #PB_Font_Underline

sFontString + "U"

EndIf

If FontStructArray()\FontStyle & #PB_Font_HighQuality

sFontString + "H"

EndIf

EndIf

SetGadgetText(#FontString, sFontString)

Break

EndIf

Wend

EndIf

If Left(\FrontColor, 5) <> "#Nooo"

If \FrontColor = ""

SetGadgetAttribute(#FrontColorPick, #PB_Button_Image, 0)

Else

If StartDrawing(ImageOutput(#FrontColorImg))

Box(0, 0, OutputWidth(), OutputHeight(), Val(\FrontColor))

StopDrawing()

SetGadgetAttribute(#FrontColorPick, #PB_Button_Image, ImageID(#FrontColorImg))

EndIf

EndIf

HideGadget(#FrontColorText, #False)

HideGadget(#FrontColorPick, #False)

EndIf

If Left(\BackColor, 5) <> "#Nooo"

If \BackColor = ""

SetGadgetAttribute(#BackColorPick, #PB_Button_Image, 0)

Else

If StartDrawing(ImageOutput(#BackColorImg))

Box(0, 0, OutputWidth(), OutputHeight(), Val(\BackColor))