not sure why i didn't add these before

doy · doy · commit 7a65bd701b30 · 2012-09-30T02:32:00.000-05:00
diff --git a/lib/Stream/Buffered/Auto.pm b/lib/Stream/Buffered/Auto.pm
@@ -0,0 +1,35 @@
+package Stream::Buffered::Auto;
+use strict;
+use parent 'Stream::Buffered';
+
+sub new {
+    my($class, undef, $max_memory_size) = @_;
+    bless {
+        _buffer => Stream::Buffered->create('PerlIO'),
+        _max => $max_memory_size,
+    }, $class;
+}
+
+sub print {
+    my $self = shift;
+    $self->{_buffer}->print(@_);
+
+    if ($self->{_max} && $self->{_buffer}->size > $self->{_max}) {
+        my $buf = $self->{_buffer}->{buffer};
+        $self->{_buffer} = Stream::Buffered->create('File'),
+        $self->{_buffer}->print($buf);
+        delete $self->{_max};
+    }
+}
+
+sub size {
+    my $self = shift;
+    $self->{_buffer}->size;
+}
+
+sub rewind {
+    my $self = shift;
+    $self->{_buffer}->rewind;
+}
+
+1;
diff --git a/lib/Stream/Buffered/File.pm b/lib/Stream/Buffered/File.pm
@@ -0,0 +1,33 @@
+package Stream::Buffered::File;
+use strict;
+use parent 'Stream::Buffered';
+
+use IO::File;
+
+sub new {
+    my $class = shift;
+
+    my $fh = IO::File->new_tmpfile;
+    $fh->binmode;
+
+    bless { fh => $fh }, $class;
+}
+
+sub print {
+    my $self = shift;
+    $self->{fh}->print(@_);
+}
+
+sub size {
+    my $self = shift;
+    $self->{fh}->flush;
+    -s $self->{fh};
+}
+
+sub rewind {
+    my $self = shift;
+    $self->{fh}->seek(0, 0);
+    $self->{fh};
+}
+
+1;
diff --git a/lib/Stream/Buffered/PerlIO.pm b/lib/Stream/Buffered/PerlIO.pm
@@ -0,0 +1,28 @@
+package Stream::Buffered::PerlIO;
+use strict;
+use parent 'Stream::Buffered';
+
+sub new {
+    my $class = shift;
+    bless { buffer => '' }, $class;
+}
+
+sub print {
+    my $self = shift;
+    $self->{buffer} .= "@_";
+}
+
+sub size {
+    my $self = shift;
+    length $self->{buffer};
+}
+
+sub rewind {
+    my $self = shift;
+    my $buffer = $self->{buffer};
+    open my $io, "<", \$buffer;
+    bless $io, 'FileHandle'; # This makes $io work as FileHandle under 5.8, .10 and .11 :/
+    return $io;
+}
+
+1;
diff --git a/t/print.t b/t/print.t
@@ -0,0 +1,38 @@
+#!/usr/bin/env perl
+use strict;
+use warnings;
+use Test::More;
+
+use Stream::Buffered;
+
+{
+    my $b = Stream::Buffered->new(-1);
+    $b->print("foo");
+    is $b->size, 3;
+    my $fh = $b->rewind;
+    is do { local $/; <$fh> }, 'foo';
+    $fh->seek(0, 0);
+}
+
+{
+    local $Stream::Buffered::MaxMemoryBufferSize = 12;
+    my $b = Stream::Buffered->new;
+    is $b->size, 0;
+    $b->print("foo") for 1..5;
+    is $b->size, 15;
+    my $fh = $b->rewind;
+    isa_ok $fh, 'IO::File';
+    is do { local $/; <$fh> }, ('foo' x 5);
+}
+
+{
+    local $Stream::Buffered::MaxMemoryBufferSize = 0;
+    my $b = Stream::Buffered->new(3);
+    $b->print("foo\n");
+    is $b->size, 4;
+    my $fh = $b->rewind;
+    isa_ok $fh, 'IO::File';
+    is do { local $/; <$fh> }, "foo\n";
+}
+
+done_testing;
