New syntax checker actionscript/mxmlc

andyearnshaw · andyearnshaw · commit 7b29bea72d8d · 2013-12-20T23:35:29.000Z
diff --git a/plugin/syntastic/registry.vim b/plugin/syntastic/registry.vim
@@ -4,6 +4,7 @@ endif
 let g:loaded_syntastic_registry = 1
 
 let s:defaultCheckers = {
+        \ 'actionscript':['mxmlc'],
         \ 'ada':         ['gcc'],
         \ 'applescript': ['osacompile'],
         \ 'asciidoc':    ['asciidoc'],
diff --git a/syntax_checkers/actionscript/mxmlc.vim b/syntax_checkers/actionscript/mxmlc.vim
@@ -0,0 +1,67 @@
+"============================================================================
+"File:        mxmlc.vim
+"Description: ActionScript syntax checker - using mxmlc
+"Maintainer:  Andy Earnshaw <andyearnshaw@gmail.com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"============================================================================
+
+if exists('g:loaded_syntastic_actionscript_mxmlc_checker')
+    finish
+endif
+let g:loaded_syntastic_actionscript_mxmlc_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+if !exists('g:syntastic_actionscript_mxmlc_conf')
+    let g:syntastic_actionscript_mxmlc_conf = ''
+endif
+
+function! SyntaxCheckers_actionscript_mxmlc_GetHighlightRegex(item)
+    let term = ''
+
+    if match(a:item['text'], "variable '") > -1
+        let term = split(a:item['text'], "'")[1]
+
+    elseif match(a:item['text'], 'expected a definition keyword') > -1
+        let term = matchlist(a:item['text'], 'not \([^\.]\+\)\.')[1]
+
+    elseif match(a:item['text'], 'undefined \%(property\|method\)') > -1
+        let term = matchlist(a:item['text'], 'undefined \%(property\|method\) \([^\. ]\+\)')[1]
+
+    elseif match(a:item['text'], 'could not be found') > -1
+        let term = matchlist(a:item['text'], ' \([^ ]\+\) could not be found')[1]
+
+    elseif match(a:item['text'], 'Type was not found') > -1
+        let term = matchlist(a:item['text'], ': \([^\.]\+\)\.')[1]
+
+    endif
+
+    return strlen(term) ? '\V\<'.term.'\>' : ''
+endfunction
+
+function! SyntaxCheckers_actionscript_mxmlc_GetLocList() dict
+    let output  = has("win32") ? 'NUL' : '/dev/null'
+    let makeprg = self.makeprgBuild({ 'args': '-output=' . output . s:Args() })
+
+    let errorformat =
+        \ '%f(%l): col: %c %trror: %m,' .
+        \ '%f(%l): col: %c %tarning: %m,'
+
+    return SyntasticMake({ 'makeprg': makeprg, 'errorformat': errorformat })
+endfunction
+
+function s:Args()
+    return !empty(g:syntastic_actionscript_mxmlc_conf) ? ' -load-config+=' . g:syntastic_actionscript_mxmlc_conf : ''
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'actionscript',
+    \ 'name': 'mxmlc'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
