Adds get-by-id / find-by-keys for 0.6.0 RC 1

seancorfield · seancorfield · commit f2d0aec8d9d9 · 2016-05-01T16:00:51.000-07:00
diff --git a/CHANGES.md b/CHANGES.md
@@ -1,3 +1,9 @@
+Changes coming in 0.6.0-rc1
+
+* Adds `get-by-id` and `find-by-keys` convenience functions (these were easy to add after the API changes in 0.6.0 and we rely very heavily on them at World Singles so putting them in the core for everyone seemed reasonable).
+* REMINDER: ALL DEPRECATED FUNCTIONALITY HAS BEEN REMOVED! [JDBC-118](http://dev.clojure.org/jira/browse/JDBC-118).
+  - See alpha2 / alpha1 below for more details.
+
 Changes in 0.6.0-alpha2
 
 * ALL DEPRECATED FUNCTIONALITY HAS BEEN REMOVED! [JDBC-118](http://dev.clojure.org/jira/browse/JDBC-118).
diff --git a/project.clj b/project.clj
@@ -2,7 +2,7 @@
 ;; develop and test java.jdbc locally. The pom.xml file is the
 ;; "system of record" as far as the project version is concerned.
 
-(defproject org.clojure/java.jdbc "0.6.0-alpha2"
+(defproject org.clojure/java.jdbc "0.6.0-rc1"
   :description "A low-level Clojure wrapper for JDBC-based access to databases."
   :parent [org.clojure/pom.contrib "0.1.2"]
   :url "https://github.com/clojure/java.jdbc"
diff --git a/src/main/clojure/clojure/java/jdbc.clj b/src/main/clojure/clojure/java/jdbc.clj
@@ -81,6 +81,27 @@ http://clojure-doc.org/articles/ecosystem/java_jdbc/home.html" }
      (str (first q) x (last q))
      (str q x q))))
 
+(defn- table-str
+  "Transform a table spec to an entity name for SQL. The table spec may be a
+  string, a keyword or a map with a single pair - table name and alias."
+  [table entities]
+  (let [entities (or entities identity)]
+    (if (map? table)
+      (let [[k v] (first table)]
+        (str (as-sql-name entities k) " " (as-sql-name entities v)))
+      (as-sql-name entities table))))
+
+(defn- kv-sql
+  "Given a sequence of column name keys and a matching sequence of column
+  values, and an entities mapping function, return a sequence of SQL fragments
+  that can be joined for part of an UPDATE SET or a SELECT WHERE clause."
+  [ks vs entities]
+  (map (fn [k v]
+         (str (as-sql-name entities k)
+              " = "
+              (if (nil? v) "NULL" "?")))
+       ks vs))
+
 (defn- ^Properties as-properties
   "Convert any seq of pairs to a java.utils.Properties instance.
    Uses as-sql-name to convert both keys and values into strings."
@@ -867,6 +888,35 @@ http://clojure-doc.org/articles/ecosystem/java_jdbc/home.html" }
                                                   (map row-fn rs))))
                                 (result-set-seq rset {:identifiers identifiers :as-arrays? as-arrays?})))))))
 
+(defn find-by-keys
+  "Given a database connection, a table name, a map of column name/value
+  pairs, and an optional options map, return any matching rows."
+  ([db table columns] (find-by-keys db table columns {}))
+  ([db table columns opts]
+   (let [entities (:entities opts identity)
+         ks (keys columns)
+         vs (vals columns)]
+     (query db (into [(str "SELECT * FROM " (table-str table entities)
+                           " WHERE " (str/join " AND "
+                                               (kv-sql ks vs entities)))]
+                     (remove nil? vs))
+            opts))))
+
+(defn get-by-id
+  "Given a database connection, a table name, a primary key value, an
+  optional primary key column name, and an optional options map, return
+  a single matching row, or nil.
+  The primary key column name defaults to :id."
+  ([db table pk-value] (get-by-id db table pk-value :id {}))
+  ([db table pk-value pk-name-or-opts]
+   (if (map? pk-name-or-opts)
+     (get-by-id db table pk-value :id pk-name-or-opts)
+     (get-by-id db table pk-value pk-name-or-opts {})))
+  ([db table pk-value pk-name opts]
+   (let [r-s-fn (or (:result-set-fn opts) identity)]
+     (find-by-keys db table {pk-name pk-value}
+                   (assoc opts :result-set-fn (comp first r-s-fn))))))
+
 (defn execute!
   "Given a database connection and a vector containing SQL (or PreparedStatement)
   followed by optional parameters, perform a general (non-select) SQL operation.
@@ -891,16 +941,6 @@ http://clojure-doc.org/articles/ecosystem/java_jdbc/home.html" }
        (with-open [con (get-connection db)]
          (execute-helper (add-connection db con)))))))
 
-(defn- table-str
-  "Transform a table spec to an entity name for SQL. The table spec may be a
-  string, a keyword or a map with a single pair - table name and alias."
-  [table entities]
-  (let [entities (or entities identity)]
-    (if (map? table)
-      (let [[k v] (first table)]
-        (str (as-sql-name entities k) " " (as-sql-name entities v)))
-      (as-sql-name entities table))))
-
 (defn- delete-sql
   "Given a table name, a where class and its parameters and an optional entities spec,
   return a vector of the SQL for that delete operation followed by its parameters. The
@@ -1051,11 +1091,7 @@ http://clojure-doc.org/articles/ecosystem/java_jdbc/home.html" }
     (cons (str "UPDATE " (table-str table entities)
                " SET " (str/join
                         ","
-                        (map (fn [k v]
-                               (str (as-sql-name entities k)
-                                    " = "
-                                    (if (nil? v) "NULL" "?")))
-                             ks vs))
+                        (kv-sql ks vs entities))
                (when where " WHERE ")
                where)
           (concat (remove nil? vs) params))))
diff --git a/src/test/clojure/clojure/java/test_jdbc.clj b/src/test/clojure/clojure/java/test_jdbc.clj
@@ -379,7 +379,11 @@
     (is (= 2 (sql/with-db-connection [con db]
                (sql/query con [(sql/prepare-statement (sql/db-connection con) "SELECT * FROM fruit" {:max-rows 2})] {:result-set-fn count}))))
     (is (= "Apple" (sql/query db ["SELECT * FROM fruit WHERE appearance = ?" "red"] {:row-fn :name :result-set-fn first})))
-    (is (= "juicy" (sql/query db ["SELECT * FROM fruit WHERE name = ?" "Orange"] {:row-fn :appearance :result-set-fn first})))))
+    (is (= "juicy" (sql/query db ["SELECT * FROM fruit WHERE name = ?" "Orange"] {:row-fn :appearance :result-set-fn first})))
+    (is (= "Apple" (:name (sql/get-by-id db :fruit 1))))
+    (is (= ["Apple"] (map :name (sql/find-by-keys db :fruit {:appearance "red"}))))
+    (is (= "Peach" (:name (sql/get-by-id db :fruit 3 :id))))
+    (is (= ["Peach"] (map :name (sql/find-by-keys db :fruit {:id 3 :cost 139}))))))
 
 (deftest test-insert-values
   (doseq [db (test-specs)]
