Excel VBA Find – A Complete Guide

SEPTEM BER 7, 2015 BY PAU L KELLY ·24 COMMEN TS

“I know well what I am fleeing from but not what I am in search of” – Michel de Montaigne

Contents [hide] [hide]

 1 Introduction
 2 What is the VBA Find Function?
o 2.1 Excel Find Dialog
o 2.2 How to Use Options With Find
 3 VBA Find Parameters
o 3.1 Important Note about Find Parameters
 4 The Find Return Value
 5 How to do a Simple Find
o 5.1 When the Value is not Found
 6 Using After with Find
o 6.1 Example 1 Without After
o 6.2 Example 2 Using After
o 6.3 Example 3 Wrapping Around
 7 Using LookIn with Find
 8 Using LookAt with Find
 9 Using SearchOrder with Find
 10 Using SearchDirection with Find
o 10.1 Using xlPrevious with After
 11 Using MatchCase with Find
 12 Using MatchByte with Find
 13 Using SearchFormat with Find
o 13.1 Using Wild Card
o 13.2 Important – Clearing Format
 14 Multiple Searches
 15 Finding the Last Cell Containing Data
 16 Finding Cells with Patterns
 17 An Alternative to using VBA Find
 18 Find and Replace
 19 What’s Next?
 20 Get the Free eBook

Introduction
This post covers everything you need to know about the VBA Find function. It explains, how to use Find, in simple terms.
It also has tons of code examples of Find you can use right now.
If you want to go straight to an example of Find then check out How to do a Simple Find.
If you want to search for text within a string then you are looking for the InStr and InStrRev functions.
If you want to find the last row or column with data then go to Finding the Last Cell Containing Data

What is the VBA Find Function?

The Find function is very commonly used in VBA. The three most important things to know about Find are:

1. The Find function is a member of Range.

2. It searches a range of cells containing a given value or format.
3. It is essentially the same as using the Find Dialog on an Excel worksheet.

Excel Find Dialog

To view the Excel Find dialog, go to the Home ribbon and click on Find & Select in the Editing section. In the menu that
appears select Find(shortcut is Ctrl + F)

When you do this the following dialog will appear

The VBA Find function uses most of the options you can see on this Dialog.

How to Use Options With Find

To use the options you pass them as parameters to the Find function. This is similar to how you use worksheet functions.
For example, the Sum function has a Range as a parameter. This means you give it a range when you use it.
The VBA Find uses parameters in the same way. You must give it the item you are searching for. This is the first
parameter and it is required.
The rest of the parameters are optional. If you don’t use them then Find will use the existing settings. We’ll see more
about this shortly.
The table in the next section shows these parameters. The sections that follow this, give examples and details of how to
use these parameters.

VBA Find Parameters

The following tables shows all the Find parameters.

Parameter Type Description Values

What Required The value you are searching for Any VBA data type e.g
String, Long

After Optional A single cell range that you start your search from Range("A5")

LookIn Optional What to search in e.g. Formulas, Values or xlValues, xlFormulas,

Parameter Type Description Values

Comments xlComments

LookAt Optional Look at a part or the whole of the cell xlWhole, xlPart

SearchOrder Optional The order to search xlByRows or

xlByColumns.

SearchDirection Optional The direction to search xlNext, xlPrevious

MatchCase Optional If search is case sensitive True or False

MatchByte Optional Used for double byte languages True or False

SearchFormat Optional Allow searching by format. The format is set using True or False
Application.FindFormat

Important Note about Find Parameters

Keep the following in mind as it can cause a lot of frustration when using Find.
As you can see from the table most of the VBA Find parameters are optional. As we said earlier, if you don’t set a Find
parameter it uses the existing setting.
For example, if you set the LookIn parameter to xlComments, it will search for a value in comments only. The next time
you run Find(either from the Dialog or from VBA) the existing LookIn setting will be Comments.
The following code shows an example of this

' Search in comments only

Range("A1:A5").Find "John", LookIn:=xlComments

' Will search comments as this is the existing setting

Range("A1:A5").Find "John"

' Search in formulas only

Range("A1:A5").Find "John", LookIn:=xlFormulas

' Will search formulas as this is the existing setting

Range("A1:A5").Find "John"
This applies to the parameters LookIn, LookAt, SearchOrder, and MatchByte.

The Find Return Value

If the search item is found then Find returns the cell with the value. That is, it returns a Range type of one cell.
If the search item is not found then Find returns an object set to Nothing.
In the following examples, you will see how to deal with the return value.

How to do a Simple Find

Let’s start with a simple example of the VBA Find. You need three things when using the Find function

1. The Range to search

2. The value you are searching for
3. The Range to store the returned cell

Let’s take the following sample data

We are going to search for the text “Jena” in the cells A1 to A5.
The following code searches for “Jena”. When it finds “Jena”, it then places the cell in the rgFound variable.

' Find the name Jena in the range A1:A5

Dim rgFound As Range

Set rgFound = Range("A1:A5").Find("Jena")

' Print cell address to Immediate Window(Ctrl + G)

Debug.Print rgFound.Address

The above code shows the most basic search you can do. If this is your first time using the VBA Find function then I
recommend you practice with a simple example like this.

When the Value is not Found

When you use the VBA Find function, there will be times when you do not find a match. You need to handle this in your
code or you will get the following error when you try to use the returned range

The following code will give this error if the text “John” is not found in the range A1 to A5

Set rgFound = Range("A1:A5").Find("John")

' Shows Error if John was not found

Debug.Print rgFound.Address

What we need to do is check the return value like the following code shows

Set rgFound= Range("A1:A5").Find("John")

If rgFound Is Nothing Then

Debug.Print "Name was not found."

Else

Debug.Print "Name found in :" & rgFound.Address

End If

Using After with Find

The After parameter is used if you want to start the search from a particular cell. This is the same as when you do a search
with Excel Find Dialog. With the dialog, the active cell is considered the Aftercell.

Example 1 Without After

Let’s look at the following code.

Set cell = Range("A1:A6").Find("Rachal")

Find will return the cell A2 as this is where the first “Rachal” is found.

Example 2 Using After

In the next example, we use after. We are telling VBA to start the search for “Rachal” after cell A2

Set cell = Range("A1:A6").Find("Rachal", After:=Range("A2"))

This will return the cell A6

Example 3 Wrapping Around
If a match is not found then the search will “wrap around”. This means it will go back to the start of the range.
In the following example, we are looking for Drucilla. We start our search After cell A2. Find will search from A3 to A6
and then will move to A1.
So the following code will return A1 as there is no text “Drucilla” from A3 to A6.

Set cell = Range("A1:A6").Find("Drucilla", After:=Range("A2"))

The search order for this example was A4, A5, A6, A1.

Using LookIn with Find

Using LookIn allows you to search in Values, Formulas or Comments.
Important Note: When a cell has text only, this text is considered a formula AND a value. See the table below for details

Cell Contains Result LookIn value is

Apple Apple Value and Formula

="App" & "le"' Apple Value only

=LEFT("Apple",4)' Appl Formula only

We are going to use the following sample data.

A2 Contains “Apple” as a value only
A3 Contains “Apple” as a formula only
A4 Contains “Apple” in the comment only

The code below searches for “Apple” in the different types

Sub UseLookIn()

Dim cell As Range

' Finds A2

Set cell = Range("A1:A4").Find("Apple", LookIn:=xlValues)

Debug.Print cell.Address
 ' Finds A3

vSet cell = Range("A1:A4").Find("Apple", LookIn:=xlFormulas)

Debug.Print cell.Address

' Finds A4

Set cell = Range("A1:A4").Find("Apple", LookIn:=xlComments)

Debug.Print cell.Address

End Sub

Using LookAt with Find

Using the LookAt function is pretty straightforward.

1. xlWhole means the search value must match the entire cell contents.
2. xlPart means the search value only has to match part of the cell.

The following example has “Apple” as part of the cell contents in A2 and it is the full contents in cell A3.

The first Find in the following code finds “Apple” in A2. The second Find is looking for a full match so finds A3.

Sub UseLookAt()

Dim cell As Range

' Finds A2

Set cell = Range("A1:A3").Find("Apple", Lookat:=xlPart)

Debug.Print cell.Address
 ' Finds A3

Set cell = Range("A1:A3").Find("Apple", Lookat:=xlWhole)

Debug.Print cell.Address

End Sub

Using SearchOrder with Find

The SearchOrder parameter allows use to search by row or by column. In the following sample data we have
two occurrences of the text “Elli”.

If we search by row we will find the “Elli” in B2 first. This is because we search in the order row 1, then row 2 etc.
If we search by column we will find the “Elli” in A5 first. This is because we search in the order column A, the Column B
etc.

The following code shows an example of using the SearchOrder with this sample data

Sub UseSearchOrder()

Dim cell As Range

' Finds B2

Set cell = Range("A1:B6").Find("Elli", SearchOrder:=xlRows)

Debug.Print cell.Address
 ' Finds A5

Set cell = Range("A1:B6").Find("Elli", SearchOrder:=xlColumns)

Debug.Print cell.Address

End Sub

Using SearchDirection with Find

SearchDirection allows you to search forward or backward. So imagine you have the range A1:A7. Searching
using xlNext will go in the order
A1, A2, A3, A4, A5, A6, A7
Searching using xlPrevious will go in the order
A7, A6, A5, A4, A3, A2, A1

Using xlNext with the sample data will return A2 as this where it finds the first match. Using xlPrevious will return A5.

' NOTE: Underscore allows breaking up a line

Sub UseSearchDirection()

Dim cell As Range

' Finds A2

Set cell = shData.Range("A1:A7") _

.Find("Elli", SearchDirection:=xlNext)

Debug.Print cell.Address
 ' Finds A5

Set cell = shData.Range("A1:A7") _

.Find("Elli", SearchDirection:=xlPrevious)

Debug.Print cell.Address

End Sub

Using xlPrevious with After

It you use the After parameter with xlPrevious then it will start before from the After cell. So if we set the After cell to be
A6 then the search order will be
A5,A4,A3,A2,A1,A7,A6.
The following code shows an example of this

Sub UseSearchDirectionAfter()

Dim cell As Range

' Finds A2

Set cell = shData.Range("A1:A7").Find("Elli" _

, After:=Range("A6"), SearchDirection:=xlPrevious)

Debug.Print cell.Address

' Finds A6

Set cell = shData.Range("A1:A7").Find("Elli" _

, After:=Range("A7"), SearchDirection:=xlPrevious)

Debug.Print cell.Address

End Sub
Using MatchCase with Find
The MatchCase parameter is used to determine if the case of the letters matters in the search. It can be set to True or False.

 True – the case of the letters must match

 False – the case of the letters does not matter

The following sample list has two entries for “Elli”. The second has a small letter e

The following code examples shows the result of setting MatchCase to True and False

Sub UseMatchCase()

Dim cell As Range

' Finds A2

Set cell = Range("A1:B6").Find("elli", MatchCase:=False)

Debug.Print cell.Address

' Finds A6

Set cell = Range("A1:B6").Find("elli", MatchCase:=True)

Debug.Print cell.Address

End Sub
Using MatchByte with Find
The MatchByte parameter is used for languages with a double byte character set. These are languages such as
Chinese/Japanese/Korean.
If you are not using them then this parameter is not relevant. They are used as follows

 True means to match only double-byte characters with double-byte characters.

 False means to double-byte characters can match with single or double-byte characters.

Using SearchFormat with Find

Search Format is a bit different than the other parameters. It allows you to search for a cell format such as font type or cell
colour.
You need to set the format first by using the Application.FindFormat property. Then you set SearchFormat to True to
search for this format.
In the following sample data, we have two cells formatted. Cell A5 is set to Bold and Cell A6 has the fill colour set to red.

The following code searches for the bold cell.

Sub UseSearchFormat()

Dim cell As Range

Application.FindFormat.Font.Bold = True

' Finds A2

Set cell = Range("A1:B6").Find("Elli", SearchFormat:=False)

Debug.Print cell.Address
 ' Finds A5

Set cell = Range("A1:B6").Find("Elli", SearchFormat:=True)

Debug.Print cell.Address

End Sub

Using Wild Card

You can search for a cell based on the format only. In other words, the value in the cell is ignored in the search. You do
this by placing “*” in the search string.
The following code searches for a cell that is formatted to red. The contents of the cell do not matter.

Sub UseSearchFormatWild()

Dim cell As Range

' Clear previous formats

Application.FindFormat.Clear

' Set format

Application.FindFormat.Interior.Color = rgbRed

' Finds A2

Set cell = Range("A1:B6").Find("*", SearchFormat:=False)

Debug.Print cell.Address

' Finds A5

Set cell = Range("A1:B6").Find("*", SearchFormat:=True)

Debug.Print cell.Address

End Sub

Important – Clearing Format

When you set the FindFormat attributes they remain in place until you set them again. This is something to watch out for.
For example, imagine you set the format to bold and then use Find. Then you set the format to font size 12 and use Find
again. The search will look for cells where the font is bold AND of size 12.
Therefore, it is a good idea to clear the format before you use it. You can clear the format by using the code

Application.FindFormat.Clear

You can see the we used this in the second SearchFormat example above.

Multiple Searches
In many cases you will want to search for multiple occurrences of the same value. To do this we use the Find function
first. Then we use the .FindNext function to find the next item.

.FindNext searches based on the setting we used in the Find. The following code shows a simple example of finding the
first and second occurrences of the text “Elli”.

Sub SearchNext()

Dim cell As Range

' Find first - A2

Set cell = Range("A1:A9").Find("Elli")

Debug.Print "Found: " & cell.Address

 ' Find second - A5

Set cell = Range("A1:A9").FindNext(cell)

Debug.Print "Found: " & cell.Address

End Sub

Sometimes you won’t know how many occurrences there is. In this case we use a loop to keep searching until we have
found all the items.
We use Find to get the first item. If we find an item we then use a Do Loop with .FindNext to find the rest of the
occurrences.
FindNext will wrap around. That is, after it finds A9 it will continue the search at A1. Therefore, we store the address of
the first cell we find. When FindNext returns this cell again we know we have found all the items.
The following code will find all the occurrences of Elli

Sub MultipleSearch()

' Get name to search

Dim name As String: name = "Elli"

' Get search range

Dim rgSearch As Range

Set rgSearch = Range("A1:A9")

Dim cell As Range

Set cell = rgSearch.Find(name)

' If not found then exit

If cell Is Nothing Then

Debug.Print "Not found"

Exit Sub

End If

' Store first cell address

Dim firstCellAddress As String

firstCellAddress = cell.Address
 ' Find all cells containing Elli

Do

Debug.Print "Found: " & cell.Address

Set cell = rgSearch.FindNext(cell)

Loop While firstCellAddress <> cell.Address

End Sub

The output from this code is

Found: $A$2
Found: $A$5
Found: $A$8

Finding the Last Cell Containing Data

A very common task in VBA is finding the last cell that contains data in a row or colum. This does not use the VBA Find
function. Instead, we use the following code to find the last row with data

' Find the last row with data in column A

LastRow = Cells(Rows.Count, 1).End(xlUp).Row

' Find the last row with data in column C

LastRow = Cells(Rows.Count, 3).End(xlUp).Row

To find the last column with data we use similar code

' Find the last column with data in row 1

lLastCol = Cells(1, Columns.Count).End(xlToLeft).Column

' Find the last column with data in row 3

lLastCol = Cells(3, Columns.Count).End(xlToLeft).Column

Finding Cells with Patterns

If you want to find cells with certain patterns then you have to use the Like operator rather than Find.
For example, to find the all the names starting with E you could use the following code

' Print all names starting with the letter E

Sub PatternMatch()

Dim cell As Range

' Go through each cell in range

For Each cell In Range("A1:A20")

' Check the pattern

If cell Like "[E]*" Then

Debug.Print cell

End If

Next

End Sub

If you want to know more about this then check out Comparing Strings using Pattern Matching.
To see a real-world example of using pattern matching check out Example 3: Check if a filename is valid.

An Alternative to using VBA Find

If you are expecting a large number of hits then using an array is a better option. You can read a range of cells to an array
very quickly and efficiently.
The following code reads the cell values to an array and then reads through the array to count the items.

Sub UseArrayToCount()

Dim arr() As Variant

' read cell range to array

arr = Sheet2.Range("A1:B25")

Dim name As Variant, cnt As Long

' Go through the array

For Each name In arr

 ' Count in the name 'Ray' is found

If name = "Ray" Then

cnt = cnt + 1

End If

Next name

Debug.Print "The number of occurrences was: " & cnt

End Sub

If you want to find out more about arrays then check out the post The Complete Guide to Using Arrays in Excel VBA.

Find and Replace

To do a find and Replace you can use the Replace function. It is very similar to using the Find function.
The replace function is outside the scope of this post although a lot of what you read here can be used with it. You can see
the details of it at Microsoft – VBA Replace Function