using BenchmarkTools
using Random
using TranscodingStreams
using CodecZstd
using ChunkCodecCore

const SUITE = BenchmarkGroup()
cbencht = SUITE["compression"] = BenchmarkGroup()
dbencht = SUITE["decompression"] = BenchmarkGroup()
cbenchd = SUITE["compression-decode"] = BenchmarkGroup()
dbenchd = SUITE["decompression-decode"] = BenchmarkGroup()
dbenchc = SUITE["decompression-size-hint"] = BenchmarkGroup()

ccodec = ZstdCompressor()
dcodec = ZstdDecompressor()
TranscodingStreams.initialize(ccodec)
TranscodingStreams.initialize(dcodec)

for N in [100, 100000, 1000000]
    u1 = rand(Xoshiro(1234), UInt8, N)
    c1 = transcode(ZstdCompressor, u1)

    u2 = rand(Xoshiro(1234), 0x00:0x01, N)
    c2 = transcode(ZstdCompressor, u2)

    f = round.(randn(Xoshiro(1234), N); base=2, digits=7)
    # byte shuffle
    u3 = vec(permutedims(reinterpret(reshape, UInt8, f),(2,1)))
    c3 = transcode(ZstdCompressor, u3)
    for (data, compressed, name) in [
        (u1, c1, "incompressible"),
        (u2, c2, "compressible-bytes"),
        (u3, c3, "byteshuffle"),
    ]
        cbencht[name][N] = @benchmarkable transcode($ccodec, $data)
        cbenchd[name][N] = @benchmarkable decode($ccodec, $data)
        dbencht[name][N] = @benchmarkable transcode($dcodec, $compressed)
        dbenchd[name][N] = @benchmarkable decode($dcodec, $compressed)
        dbenchc[name][N] = @benchmarkable decode($dcodec, $compressed; size_hint=$(length(data)))
    end
end