Java 12: add QL for switch expressions, etc

yh-semmle · yh-semmle · commit 38705038a80f · 2019-04-30T10:59:04.000-04:00
diff --git a/java/ql/src/semmle/code/java/Expr.qll b/java/ql/src/semmle/code/java/Expr.qll
@@ -1093,6 +1093,33 @@ class ConditionalExpr extends Expr, @conditionalexpr {
   override string toString() { result = "...?...:..." }
 }
 
+/** A `switch` expression. */
+class SwitchExpr extends Expr, @switchexpr {
+  /** Gets an immediate child statement of this `switch` expression. */
+  Stmt getAStmt() { result.getParent() = this }
+
+  /**
+   * Gets the immediate child statement of this `switch` expression
+   * that occurs at the specified (zero-based) position.
+   */
+  Stmt getStmt(int index) { result = this.getAStmt() and result.getIndex() = index }
+
+  /**
+   * Gets a case of this `switch` expression,
+   * which may be either a normal `case` or a `default`.
+   */
+  SwitchCase getACase() { result = getAConstCase() or result = getDefaultCase() }
+
+  /** Gets a (non-default) `case` of this `switch` expression. */
+  ConstCase getAConstCase() { result.getParent() = this }
+
+  /** Gets the `default` case of this switch expression, if any. */
+  DefaultCase getDefaultCase() { result.getParent() = this }
+
+  /** Gets the expression of this `switch` expression. */
+  Expr getExpr() { result.getParent() = this }
+}
+
 /** A parenthesised expression. */
 class ParExpr extends Expr, @parexpr {
   /** Gets the expression inside the parentheses. */
diff --git a/java/ql/src/semmle/code/java/Statement.qll b/java/ql/src/semmle/code/java/Statement.qll
@@ -400,23 +400,43 @@ class SwitchStmt extends Stmt, @switchstmt {
 }
 
 /**
- * A case of a `switch` statement.
+ * A case of a `switch` statement or expression.
  *
  * This includes both normal `case`s and the `default` case.
  */
 class SwitchCase extends Stmt, @case {
+  /** Gets the switch statement to which this case belongs, if any. */
   SwitchStmt getSwitch() { result.getACase() = this }
+
+  /** Gets the switch expression to which this case belongs, if any. */
+  SwitchExpr getSwitchExpr() { result.getACase() = this }
+
+  /** Holds if this `case` is a switch labeled rule of the form `... -> ...`. */
+  predicate isRule() {
+    exists(Expr e | e.getParent() = this | e.getIndex() = -1)
+    or
+    exists(Stmt s | s.getParent() = this | s.getIndex() = -1)
+  }
 }
 
 /** A constant `case` of a switch statement. */
 class ConstCase extends SwitchCase {
   ConstCase() { exists(Expr e | e.getParent() = this | e.getIndex() >= 0) }
 
-  /** Gets the expression of this `case`. */
+  /** Gets the `case` constant at index 0. */
   Expr getValue() { result.getParent() = this and result.getIndex() = 0 }
 
+  /** Gets the `case` constant at the specified index. */
+  Expr getValue(int i) { result.getParent() = this and result.getIndex() = i and i >= 0 }
+
+  /** Gets the expression on the right-hand side of the arrow, if any. */
+  Expr getRuleExpression() { result.getParent() = this and result.getIndex() = -1 }
+
+  /** Gets the statement on the right-hand side of the arrow, if any. */
+  Stmt getRuleStatement() { result.getParent() = this and result.getIndex() = -1 }
+
   /** Gets a printable representation of this statement. May include more detail than `toString()`. */
-  override string pp() { result = "case ...:" }
+  override string pp() { result = "case ..." }
 
   /** This statement's Halstead ID (used to compute Halstead metrics). */
   override string getHalsteadID() { result = "ConstCase" }
@@ -552,9 +572,17 @@ class BreakStmt extends Stmt, @breakstmt {
   /** Holds if this `break` statement has an explicit label. */
   predicate hasLabel() { exists(string s | s = this.getLabel()) }
 
+  /** Gets the value of this `break` statement, if any. */
+  Expr getValue() { result.getParent() = this }
+
+  /** Holds if this `break` statement has a value. */
+  predicate hasValue() { exists(Expr e | e.getParent() = this) }
+
   /** Gets a printable representation of this statement. May include more detail than `toString()`. */
   override string pp() {
-    if this.hasLabel() then result = "break " + this.getLabel() else result = "break"
+    if this.hasLabel()
+    then result = "break " + this.getLabel()
+    else (if this.hasValue() then result = "break ..." else result = "break")
   }
 
   /** This statement's Halstead ID (used to compute Halstead metrics). */
