C#: Only resolve a single, canonical type for each typeref.

calumgrant · hvitved · commit f61fdc6891e0 · 2020-09-02T10:52:04.000+02:00
diff --git a/csharp/ql/src/semmle/code/csharp/Type.qll b/csharp/ql/src/semmle/code/csharp/Type.qll
@@ -1012,5 +1012,63 @@ class TypeMention extends @type_mention {
 @type_or_ref getTypeRef(@type type) {
   result = type
   or
-  typeref_type(result, type)
+  type = result.(TypeRefs::TypeRef).getCanonicalType()
+}
+
+/**
+ * Module for reasoning about typerefs.
+ */
+// private 
+module TypeRefs {
+  /**
+   * A typeref is a reference to a type in some assembly.
+   * Often, a type can be present in multiple assemblies.
+   */
+  class TypeRef extends @typeref {
+    string getName() { typerefs(this, result) }
+
+    string toString() { result = getName() }
+
+    Type getAType() { typeref_type(this, result) }
+
+    /**
+     * Gets the "canonical type" represented by a typeref.
+     * This is because a typeref can reference multiple types, or a type with the same
+     * fully qualified name can exist in multiple assemblies.
+     * The canonical type is an arbitrarily chosen type from the list of candidate types.
+     */
+    Type getCanonicalType() {
+      result = this.getAType() and
+      isCanonicalType(result)
+    }
+  }
+
+  /** Gets the location of a type. */
+  Location typeLocation(Type t) {
+    type_location(t, result)
+    or
+    exists(Type decl | constructed_generic(decl, t) and result = typeLocation(decl))
+  }
+
+  /** Gets a "canonical location" for a type. A type has only one canonical location. */
+  Location canonicalTypeLocation(Type t) {
+    result = typeLocation(t) and
+    not locationIsBetter(result, typeLocation(t))
+  }
+
+  pragma[inline]
+  private predicate locationIsBetter(Location typeLocation, Location betterLocation) {
+    typeLocation.(Assembly).getFullName() < betterLocation.(Assembly).getFullName()
+    or
+    typeLocation instanceof Assembly and betterLocation instanceof SourceLocation
+    or
+    typeLocation.(SourceLocation).getFile().getAbsolutePath() < betterLocation.(SourceLocation).getFile().getAbsolutePath()
+  }
+
+  predicate isCanonicalType(Type type) {
+    not exists(TypeRef tr |
+      type = tr.getAType() and
+      locationIsBetter(canonicalTypeLocation(type), canonicalTypeLocation(tr.getAType()))
+    )
+  }
 }
diff --git a/csharp/ql/test/library-tests/aliases/aliases2.expected b/csharp/ql/test/library-tests/aliases/aliases2.expected
@@ -1,9 +1,3 @@
-| Program.cs:18:21:18:22 | c1 | Assembly1.dll:0:0:0:0 | Class |
-| Program.cs:18:21:18:22 | c1 | Assembly2.dll:0:0:0:0 | Class |
 | Program.cs:18:21:18:22 | c1 | Program.cs:10:7:10:11 | Class |
-| Program.cs:19:21:19:22 | c2 | Assembly1.dll:0:0:0:0 | Class |
-| Program.cs:19:21:19:22 | c2 | Assembly2.dll:0:0:0:0 | Class |
 | Program.cs:19:21:19:22 | c2 | Program.cs:10:7:10:11 | Class |
-| Program.cs:20:15:20:16 | c3 | Assembly1.dll:0:0:0:0 | Class |
-| Program.cs:20:15:20:16 | c3 | Assembly2.dll:0:0:0:0 | Class |
 | Program.cs:20:15:20:16 | c3 | Program.cs:10:7:10:11 | Class |
