module "audit_event_bus" {
  source = "terraform-aws-modules/eventbridge/aws"
  bus_name = local.audit_namespace

  archives = {
    (local.audit_namespace) = {
      retention_days = var.audit_event_retention_days
    }
  }

  create_bus     = true
  create_rules   = false
  create_targets = false
}

# Using BASIC auth with dummy values as the webhook URL is self-authenticating
resource "aws_cloudwatch_event_connection" "slack" {
  name               = "slack-connection"
  authorization_type = "BASIC"
  auth_parameters {
    basic {
      username = "dummy" # Required by AWS but not used
      password = "dummy" # Required by AWS but not used
    }
  }
}

resource "aws_cloudwatch_event_rule" "audit_slack" {
  event_bus_name = module.audit_event_bus.eventbridge_bus_name
  name           = "${local.audit_namespace}-trigger-slack"
  event_pattern = jsonencode({
    "detail-type" = ["AuditedAction"]
    detail = {
      action = ["BUSINESS_DIRECTOR_UPDATE"]
    }
  })
}
resource "aws_cloudwatch_event_api_destination" "audit_slack" {
  name        = "slack-api-destination"
  description = "Slack API Destination"
  
  invocation_endpoint              = "https://example.com"
  http_method                      = "POST"
  invocation_rate_limit_per_second = 20
  connection_arn                   = aws_cloudwatch_event_connection.slack.arn
}

resource "aws_cloudwatch_event_target" "audit_slack" {
  event_bus_name = module.audit_event_bus.eventbridge_bus_name
  rule           = aws_cloudwatch_event_rule.audit_slack.name
  arn            = aws_cloudwatch_event_api_destination.audit_slack.arn
  role_arn       = aws_iam_role.eventbridge_target_role.arn
  target_id      = "slack-notification"

  input_transformer {
    input_paths = {
      text = "$.detail.event"
    }

    input_template = <<EOF
{
  "channel": "test",
  "text": "<text>"
}
EOF
  }

  dead_letter_config {
    arn = aws_sqs_queue.merchant_deadletter.arn
  }
}