Added test for ut_coverage_sonar_reporter

Added missing privileges to mock data in ut3 schema. Added ability to mock coverage.
utPLSQL · Pazus · Aug 21, 2017 · Jul 21, 2017 · Jul 22, 2017 · Jul 23, 2017
commit cd0d954f56d8ffbba99bcc7a92ba48fa64036e94
diff --git a/.travis/install.sh b/.travis/install.sh
@@ -30,6 +30,6 @@ set feedback off
 
 set feedback on
 --Needed for testing coverage outside of main UT3 schema.
-grant create any procedure, drop any procedure, execute any procedure, create any type, drop any type, execute any type, under any type, select any table, delete any table, create any table, drop any table, alter any table, select any dictionary to $UT3_TESTER;
+grant create any procedure, drop any procedure, execute any procedure, create any type, drop any type, execute any type, under any type, select any table, update any table, insert any table, delete any table, create any table, drop any table, alter any table, select any dictionary to $UT3_TESTER;
 exit
 SQL
diff --git a/source/core/coverage/ut_coverage.pkb b/source/core/coverage/ut_coverage.pkb
@@ -16,6 +16,8 @@ create or replace package body ut_coverage is
   limitations under the License.
   */
 
+  type t_source_lines is table of binary_integer;
+
   -- The source query has two important transformations done in it.
   -- the flag: to_be_skipped ='Y' is set for a line of code that is badly reported by DBMS_PROFILER as executed 0 times.
   -- This includes lines that are:
@@ -157,13 +159,25 @@ create or replace package body ut_coverage is
     ut_coverage_helper.coverage_stop_develop();
   end;
 
+  function get_lines_to_skip(a_object_owner varchar2, a_object_name varchar2) return t_source_lines is
+    l_result    t_source_lines;
+  begin
+    select line
+      bulk collect into l_result
+      from ut_coverage_sources_tmp o
+     where to_be_skipped = 'Y'
+       and o.owner = a_object_owner
+       and o.name = a_object_name;
+
+    return l_result;
+  end;
+
   function get_coverage_data(a_coverage_options ut_coverage_options) return t_coverage is
     l_line_calls       ut_coverage_helper.unit_line_calls;
     l_result           t_coverage;
     l_new_unit         t_unit_coverage;
     l_skipped_objects  ut_object_names := ut_object_names();
-
-    type t_source_lines is table of binary_integer;
+    l_lines_to_skip    t_source_lines;
     line_no            binary_integer;
   begin
 
@@ -178,24 +192,21 @@ create or replace package body ut_coverage is
     end if;
 
     for src_object in (
-      select o.owner, o.name, o.full_name, max(o.line) lines_count,
-             cast(
-               collect(decode(to_be_skipped, 'Y', to_char(line))) as ut_varchar2_list
-             ) to_be_skipped_list
+      select o.owner, o.name, o.full_name, max(o.line) lines_count
         from ut_coverage_sources_tmp o
        group by o.owner, o.name, o.full_name
     ) loop
 
+      l_lines_to_skip := get_lines_to_skip( src_object.owner, src_object.name );
+
       --get coverage data
       l_line_calls := ut_coverage_helper.get_raw_coverage_data( src_object.owner, src_object.name );
 
       --if there is coverage, we need to filter out the garbage (badly indicated data from dbms_profiler)
       if l_line_calls.count > 0 then
         --remove lines that should not be indicted as meaningful
-        for i in 1 .. src_object.to_be_skipped_list.count loop
-          if src_object.to_be_skipped_list(i) is not null then
-            l_line_calls.delete(src_object.to_be_skipped_list(i));
-          end if;
+        for i in 1 .. l_lines_to_skip.count loop
+          l_line_calls.delete(l_lines_to_skip(i));
         end loop;
       end if;
 

diff --git a/source/core/coverage/ut_coverage_helper.pkb b/source/core/coverage/ut_coverage_helper.pkb
@@ -109,5 +109,13 @@ create or replace package body ut_coverage_helper is
     end loop;
     return l_results;
   end;
+
+  procedure mock_coverage_id(a_coverage_id integer) is
+  begin
+    if g_develop_mode and g_is_started then
+      g_coverage_id := a_coverage_id;
+    end if;
+  end;
+
 end;
 /
diff --git a/source/core/coverage/ut_coverage_helper.pks b/source/core/coverage/ut_coverage_helper.pks
@@ -38,5 +38,11 @@ create or replace package ut_coverage_helper authid definer is
   procedure coverage_resume;
 
   function get_raw_coverage_data(a_object_owner varchar2, a_object_name varchar2) return unit_line_calls;
+
+  /***
+  * Allows overwriting of private global variable g_coverage_id
+  * Used internally, only for unit testing of the framework only
+  */
+  procedure mock_coverage_id(a_coverage_id integer);
 end;
 /
diff --git a/test/ut_reporters/test_coverage.pkb b/test/ut_reporters/test_coverage.pkb
@@ -0,0 +1,84 @@
+create or replace package body test_coverage is
+
+  g_run_id integer;
+
+  function get_mock_run_id return integer is
+    v_result integer;
+  begin
+    select min(runid) - 1 into v_result
+      from ut3.plsql_profiler_runs;
+    return v_result;
+  end;
+
+  procedure create_dummy_coverage_package is
+  begin
+    execute immediate q'[create or replace package DUMMY_COVERAGE is
+      procedure do_stuff;
+    end;]';
+    execute immediate q'[create or replace package body DUMMY_COVERAGE is
+      procedure do_stuff is
+      begin
+        if 1 = 2 then
+          dbms_output.put_line('should not get here');
+        else
+          dbms_output.put_line('should get here');
+        end if;
+      end;
+    end;]';
+  end;
+
+  procedure create_dummy_coverage_test is
+  begin
+    execute immediate q'[create or replace package TEST_DUMMY_COVERAGE is
+      --%suite(dummy coverage test)
+
+      --%test
+      procedure test_do_stuff;
+    end;]';
+    execute immediate q'[create or replace package body TEST_DUMMY_COVERAGE is
+      procedure test_do_stuff is
+      begin
+        dummy_coverage.do_stuff;
+      end;
+    end;]';
+  end;
+
+  procedure mock_coverage_data(a_run_id integer) is
+    c_unit_id   constant integer := 1;
+  begin
+    insert into ut3.plsql_profiler_runs ( runid, run_owner, run_date, run_comment)
+    values(a_run_id, user, sysdate, 'unit testing utPLSQL');
+
+    insert into ut3.plsql_profiler_units ( runid, unit_number, unit_type, unit_owner, unit_name)
+    values(a_run_id, c_unit_id, 'PACKAGE BODY', 'UT3_TESTER', 'DUMMY_COVERAGE');
+
+    insert into ut3.plsql_profiler_data ( runid,  unit_number, line#, total_occur, total_time)
+    select a_run_id, c_unit_id,     4,           1, 1  from dual union all
+    select a_run_id, c_unit_id,     5,           0, 0  from dual union all
+    select a_run_id, c_unit_id,     7,           1, 1  from dual;
+  end;
+
+  procedure setup_dummy_coverage is
+    pragma autonomous_transaction;
+  begin
+    create_dummy_coverage_package();
+    create_dummy_coverage_test();
+    g_run_id := get_mock_run_id();
+    ut3.ut_coverage_helper.mock_coverage_id(g_run_id);
+    mock_coverage_data(g_run_id);
+    commit;
+  end;
+
+  procedure cleanup_dummy_coverage is
+    pragma autonomous_transaction;
+  begin
+    execute immediate q'[drop package test_dummy_coverage]';
+    execute immediate q'[drop package dummy_coverage]';
+    delete from ut3.plsql_profiler_data where runid = g_run_id;
+    delete from ut3.plsql_profiler_units where runid = g_run_id;
+    delete from ut3.plsql_profiler_runs where runid = g_run_id;
+    commit;
+  end;
+
+end;
+/
diff --git a/test/ut_reporters/test_coverage.pks b/test/ut_reporters/test_coverage.pks
@@ -0,0 +1,13 @@
+create or replace package test_coverage is
+
+  --%suite
+  --%suitepath(utplsql.core)
+
+  --%beforeall
+  procedure setup_dummy_coverage;
+
+  --%afterall
+  procedure cleanup_dummy_coverage;
+
+end;
+/
diff --git a/test/ut_reporters/test_coverage_sonar_reporter.pkb b/test/ut_reporters/test_coverage_sonar_reporter.pkb
@@ -0,0 +1,34 @@
+create or replace package body test_coverage_sonar_reporter is
+
+  procedure report_on_file is
+    v_run_id    integer;
+    l_results   ut3.ut_varchar2_list;
+    l_expected  clob;
+    l_actual    clob;
+  begin
+    --Arrange
+    l_expected := '<coverage version="1">
+<file path="test/dummy_coverage.pkb">
+<lineToCover lineNumber="4" covered="true"/>
+<lineToCover lineNumber="5" covered="false"/>
+<lineToCover lineNumber="7" covered="true"/>
+</file>
+</coverage>';
+    --Act
+    select *
+      bulk collect into l_results
+      from table(
+        ut3.ut.run(
+          a_path => 'test_dummy_coverage',
+          a_reporter=> ut3.ut_coverage_sonar_reporter( ),
+          a_source_files => ut3.ut_varchar2_list( 'test/dummy_coverage.pkb' ),
+          a_test_files => ut3.ut_varchar2_list( )
+        )
+      );
+    l_actual := ut3.ut_utils.table_to_clob(l_results);
+    --Assert
+    ut.expect(l_actual).to_equal(l_expected);
+  end;
+
+end;
+/
diff --git a/test/ut_reporters/test_coverage_sonar_reporter.pks b/test/ut_reporters/test_coverage_sonar_reporter.pks
@@ -0,0 +1,10 @@
+create or replace package test_coverage_sonar_reporter is
+
+  --%suite(ut_coverge_sonar_reporter)
+  --%suitepath(utplsql.core.test_coverage.reporters)
+
+  --%test(reports on a project file mapped to database object)
+  procedure report_on_file;
+
+end;
+/