Merge branch 'develop' into feature/annotations_restructuring

# Conflicts: # source/core/ut_utils.pkb # source/core/ut_utils.pks
utPLSQL · jgebal · Oct 26, 2017 · Oct 6, 2017 · Oct 6, 2017 · Oct 7, 2017
commit e114aaec711902b1acb7f9266fad0205945a0457
diff --git a/source/core/ut_utils.pkb b/source/core/ut_utils.pkb
@@ -400,6 +400,57 @@ create or replace package body ut_utils is
     return l_result;
   end;
 
+  procedure save_dbms_output_to_cache is
+    l_status number;
+    l_line   varchar2(32767);
+    l_line_no integer := 1;
+    l_lines  ut_varchar2_rows := ut_varchar2_rows();
+    c_lines_limit constant integer := 100;
+    pragma autonomous_transaction;
+
+    procedure flush_lines is
+    begin
+      insert into ut_dbms_output_cache (seq_no,text)
+        select rownum, column_value
+        from table(l_lines);
+      l_lines.delete;
+    end;
+  begin
+    loop
+      dbms_output.get_line(line => l_line, status => l_status);
+      exit when l_status = 1;
+      l_lines := l_lines multiset union all ut_utils.convert_collection(ut_utils.clob_to_table(l_line||chr(7),4000));
+      if l_lines.count > c_lines_limit then
+        flush_lines();
+      end if;
+    end loop;
+    flush_lines();
+    commit;
+  end;
+
+  procedure read_cache_to_dbms_output is
+    l_lines_data sys_refcursor;
+    l_lines  ut_varchar2_rows;
+    c_lines_limit constant integer := 100;
+    pragma autonomous_transaction;
+  begin
+    open l_lines_data for select text from ut_dbms_output_cache order by seq_no;
+    loop
+      fetch l_lines_data bulk collect into l_lines limit c_lines_limit;
+      for i in 1 .. l_lines.count loop
+        if substr(l_lines(i),-1) = chr(7) then
+          dbms_output.put_line(rtrim(l_lines(i),chr(7)));
+        else
+          dbms_output.put(l_lines(i));
+        end if;
+      end loop;
+      exit when l_lines_data%notfound;
+    end loop;
+    delete from ut_dbms_output_cache;
+    commit;
+  end;
+
+
   function ut_owner return varchar2 is
   begin
     return sys_context('userenv','current_schema');

diff --git a/source/core/ut_utils.pks b/source/core/ut_utils.pks
@@ -244,6 +244,21 @@ create or replace package ut_utils authid definer is
   function to_version(a_version_no varchar2) return t_version;
 
 
+  /**
+  * Saves data from dbms_output buffer into a global temporary table (cache)
+  *   used to store dbms_output buffer captured before the run
+  *
+  */
+  procedure save_dbms_output_to_cache;
+
+  /**
+  * Reads data from global temporary table (cache) abd puts it back into dbms_output
+  *   used to recover dbms_output buffer data after a run is complete
+  *
+  */
+  procedure read_cache_to_dbms_output;
+
+
   /**
    * Function is used to reference to utPLSQL owned objects in dynamic sql statements executed from packages with invoker rights
    *