Adding set of tests:

core/test_file_mapper core/test_output_buffer core/test_suite_manager core/test_ut_executable
utPLSQL · jgebal · Apr 3, 2019 · Mar 22, 2019 · Mar 23, 2019 · Mar 24, 2019
commit 30b0cfef62d494d8970a83e6bd422d7d3c5feb00
diff --git a/test/install_ut3_tester_tests.sql b/test/install_ut3_tester_tests.sql
@@ -16,6 +16,9 @@ alter session set plsql_optimize_level=0;
 @@ut3_tester/core/test_ut_test.pks
 @@ut3_tester/core/test_ut_suite.pks
 @@ut3_tester/core/test_ut_executable.pks
+@@ut3_tester/core/test_suite_manager.pks
+@@ut3_tester/core/test_file_mapper.pks
+@@ut3_tester/core/test_output_buffer.pks
 
 
 @@ut3_tester/core.pkb
@@ -28,6 +31,9 @@ alter session set plsql_optimize_level=0;
 @@ut3_tester/core/test_ut_test.pkb
 @@ut3_tester/core/test_ut_suite.pkb
 @@ut3_tester/core/test_ut_executable.pkb
+@@ut3_tester/core/test_suite_manager.pkb
+@@ut3_tester/core/test_file_mapper.pkb
+@@ut3_tester/core/test_output_buffer.pkb
 
 
 set linesize 200

diff --git a/test/ut3_tester/core/test_file_mapper.pkb b/test/ut3_tester/core/test_file_mapper.pkb
@@ -0,0 +1,45 @@
+create or replace package body test_file_mapper is
+
+  procedure default_mappings is
+    l_actual   ut3.ut_file_mappings;
+    l_expected ut3.ut_file_mappings;
+  begin
+    --Arrange
+    l_expected := ut3.ut_file_mappings(
+      ut3.ut_file_mapping('C:\tests\helpers\core.pkb',sys_context('USERENV', 'CURRENT_USER'),'CORE','PACKAGE BODY'),
+      ut3.ut_file_mapping('tests/helpers/test_file_mapper.pkb',sys_context('USERENV', 'CURRENT_USER'),'TEST_FILE_MAPPER','PACKAGE BODY')
+    );
+    --Act
+    l_actual := ut3.ut_file_mapper.build_file_mappings(
+        ut3.ut_varchar2_list(
+        'C:\tests\helpers\core.pkb',
+        'tests/helpers/test_file_mapper.pkb'
+      )
+    );
+    --Assert
+    ut.expect(anydata.convertCollection(l_actual)).to_equal(anydata.convertCollection(l_expected));
+  end;
+
+  procedure specific_owner is
+    l_actual   ut3.ut_file_mappings;
+    l_expected ut3.ut_file_mappings;
+  begin
+    --Arrange
+    l_expected := ut3.ut_file_mappings(
+      ut3.ut_file_mapping('C:\source\core\types\ut_file_mapping.tpb','UT3','UT_FILE_MAPPING','TYPE BODY'),
+      ut3.ut_file_mapping('source/core/ut_file_mapper.pkb','UT3','UT_FILE_MAPPER','PACKAGE BODY')
+    );
+    --Act
+    l_actual := ut3.ut_file_mapper.build_file_mappings(
+      'UT3',
+      ut3.ut_varchar2_list(
+        'C:\source\core\types\ut_file_mapping.tpb',
+        'source/core/ut_file_mapper.pkb'
+      )
+    );
+    --Assert
+    ut.expect(anydata.convertCollection(l_actual)).to_equal(anydata.convertCollection(l_expected));
+  end;
+
+end;
+/
diff --git a/test/ut3_tester/core/test_file_mapper.pks b/test/ut3_tester/core/test_file_mapper.pks
@@ -0,0 +1,13 @@
+create or replace package test_file_mapper is
+
+  --%suite(file_mapper)
+  --%suitepath(utplsql.framework_tester.core)
+
+  --%test(Maps file paths into database objects using default mappings)
+  procedure default_mappings;
+
+  --%test(Used specified object owner to perform mapping when files have no owner indication)
+  procedure specific_owner;
+
+end;
+/
diff --git a/test/ut3_tester/core/test_output_buffer.pkb b/test/ut3_tester/core/test_output_buffer.pkb
@@ -0,0 +1,96 @@
+create or replace package body test_output_buffer is
+
+  procedure test_receive is
+    l_actual_text        clob;
+    l_actual_item_type   varchar2(1000);
+    l_remaining          integer;
+    l_expected_text      clob;
+    l_expected_item_type varchar2(1000);
+    l_buffer             ut3.ut_output_buffer_base;
+  begin
+    --Arrange
+    l_buffer        := ut3.ut_output_table_buffer();
+    l_expected_text := to_clob(lpad('a text', 31000, ',a text'))
+      || chr(10) || to_clob(lpad('a text', 31000, ',a text'))
+      || chr(13) || to_clob(lpad('a text', 31000, ',a text'))
+      || chr(13) || chr(10) || to_clob(lpad('a text', 31000, ',a text')) || to_clob(lpad('a text', 31000, ',a text'));
+    l_expected_item_type := lpad('some item type',1000,'-');
+    --Act
+    l_buffer.send_clob(l_expected_text, l_expected_item_type);
+    l_buffer.close();
+
+    select text, item_type
+      into l_actual_text, l_actual_item_type
+      from table(l_buffer.get_lines(0,0));
+
+    --Assert
+    ut.expect(l_actual_text).to_equal(l_expected_text);
+    ut.expect(l_actual_item_type).to_equal(l_expected_item_type);
+
+    select count(1) into l_remaining from table(ut3_tester_helper.run_helper.ut_output_buffer_tmp) 
+      where output_id = l_buffer.output_id;
+
+    ut.expect(l_remaining).to_equal(0);
+  end;
+
+  procedure test_doesnt_send_on_null_text is
+    l_cur    sys_refcursor;
+    l_result integer;
+    l_buffer ut3.ut_output_buffer_base := ut3.ut_output_table_buffer();
+  begin
+    ut3_tester_helper.run_helper.delete_buffer();
+    --Act
+    l_buffer.send_line(null);
+
+    open l_cur for select * from table(ut3_tester_helper.run_helper.ut_output_buffer_tmp);
+    ut.expect(l_cur).to_be_empty;
+  end;
+
+  procedure test_send_line is
+    l_result   varchar2(4000);
+    c_expected constant varchar2(4000) := lpad('a text',4000,',a text');
+    l_buffer   ut3.ut_output_buffer_base := ut3.ut_output_table_buffer();
+  begin
+    l_buffer.send_line(c_expected);
+
+    select text into l_result from table(ut3_tester_helper.run_helper.ut_output_buffer_tmp) where output_id = l_buffer.output_id;
+
+    ut.expect(l_result).to_equal(c_expected);
+  end;
+
+  procedure test_waiting_for_data is
+    l_result    clob;
+    l_remaining integer;
+    l_expected  clob;
+    l_buffer    ut3.ut_output_buffer_base := ut3.ut_output_table_buffer();
+    l_start     timestamp;
+    l_duration  interval day to second;
+  begin
+    --Arrange
+    l_expected := 'a text';
+    l_buffer.send_line(l_expected);
+    l_start := localtimestamp;
+    --Act
+    begin
+      select text into l_result from table(l_buffer.get_lines(1,1));
+      ut.fail('Expected a timeout exception but nothing was raised');
+    exception 
+      when others then
+        l_duration := localtimestamp - l_start;
+      --Assert
+      --Fetches data from output
+      ut.expect(l_result).to_equal(l_expected);
+      --Throws a timeout exception
+      ut.expect(dbms_utility.format_error_stack()).to_match('ORA'||ut3.ut_utils.gc_out_buffer_timeout);
+      --Waited for one second
+      ut.expect(l_duration).to_be_greater_than(interval '0.99' second);
+    end;
+
+    select count(1) into l_remaining from table(ut3_tester_helper.run_helper.ut_output_buffer_tmp) where output_id = l_buffer.output_id;
+    --Data got removed from output buffer
+    ut.expect(l_remaining).to_equal(0);
+
+  end;
+
+end test_output_buffer;
+/
diff --git a/test/ut3_tester/core/test_output_buffer.pks b/test/ut3_tester/core/test_output_buffer.pks
@@ -0,0 +1,19 @@
+create or replace package test_output_buffer is
+
+  --%suite(output_buffer)
+  --%suitepath(utplsql.framework_tester.core)
+
+  --%test(Receives a line from buffer table and deletes)
+  procedure test_receive;
+
+  --%test(Does not send line if null text given)
+  procedure test_doesnt_send_on_null_text;
+
+  --%test(Sends a line into buffer table)
+  procedure test_send_line;
+
+  --%test(Waits For The Data To Appear For Specified Time)
+  procedure test_waiting_for_data;
+
+end test_output_buffer;
+/